
    Enact

A thin, behaviour-based action layer for application write operations. Enact standardizes the shape of every write:
load → authorize → cast → validate → resolve → execute → after_commit
The value is the uniform pipeline shape, the actor context, and the closed error taxonomy — not any novel validation or persistence machinery. Enact orchestrates; Ecto does the work: validation is Ecto changesets, input casting is Ecto embedded schemas, persistence is your existing schemas and changesets. No DSL, no parallel type system, no validation vocabulary.
Installation
def deps do
  [
    {:enact, "~> 0.1.0"}
  ]
end
Configure the default repo (or pass repo: per call):
config :enact, repo: MyApp.Repo
A complete action
defmodule MyApp.Projects.Actions.CreateProject do
  use Enact.Action

  alias MyApp.Accounts
  alias MyApp.Projects.Inputs.ProjectInput
  alias MyApp.Projects.Project

  @impl Enact.Action
  def input, do: ProjectInput

  @impl Enact.Action
  def authorize(ctx), do: MyApp.Policy.can?(ctx.actor, :create_project)

  @impl Enact.Action
  def resolvers do
    [owner: {:owner_id, &fetch_owner/2}]
  end

  @impl Enact.Action
  def execute(changeset, ctx) do
    updates =
      changeset
      |> Enact.updates(ctx)
      |> Map.put(:owner_id, ctx.assigns.owner.id)

    %Project{org_id: ctx.actor.org.id}
    |> Project.changeset(updates)
    |> ctx.repo.insert()
  end

  @impl Enact.Action
  def after_commit(project, _ctx) do
    MyApp.Analytics.track(:project_created, project)
  end

  # the context owns the trust-anchor-scoped query; the fetcher adapts
  # its result to the resolver contract
  defp fetch_owner(public_id, ctx) do
    case Accounts.get_org_user(ctx.actor, public_id) do
      nil -> :error
      user -> {:ok, user}
    end
  end
end
Application callers go through a context one-liner that forwards to Enact.run/3 (see the Phoenix guide). Action tests and IEx may call the runner directly:
case Projects.create_project(params, actor: conn.assigns.current_scope) do
  {:ok, project} -> ...
  {:error, %Enact.Error{type: :invalid, changeset: changeset}} -> ...
end
The actor is always explicit and required — actor: nil raises, and every write path answers "as whom?". Anonymous callers pass an explicit anonymous actor (see Enact.Actor), permitted only by actions declaring anonymous?: true.
Input schemas are just Ecto
Inputs are embedded-schema modules implementing the Enact.InputSchema behaviour — changeset/3 heads per mode, a fields/1 introspection manifest, and (for patch-mode use) a from_subject/1 projection that lets validate_required and cross-field get_field/2 rules work unmodified on PATCH:
defmodule MyApp.Projects.Inputs.ProjectInput do
  use Ecto.Schema
  use Enact.InputSchema
  import Ecto.Changeset

  @primary_key false
  embedded_schema do
    field :name, :string
    field :slug, :string
    field :owner_id, :string
  end

  @all ~w(name slug owner_id)a
  @patch @all -- [:slug]
  # owner_id required, so the resolver always runs and execute can rely
  # on ctx.assigns.owner being present
  @required ~w(name slug owner_id)a

  @impl Enact.InputSchema
  def changeset(base, params, :create) do
    base
    |> cast_input(params, @all)
    |> validate_required(@required)
  end

  def changeset(base, params, :patch) do
    base
    |> cast_input(params, @patch)
    |> validate_required(@required)
  end

  @impl Enact.InputSchema
  def fields(:create), do: @all
  def fields(:patch), do: @patch

  @impl Enact.InputSchema
  def from_subject(project) do
    %__MODULE__{
      name: project.name,
      slug: project.slug,
      owner_id: MyApp.PublicIds.encode(:user, project.owner_id)
    }
  end
end
Enact.updates/2 extracts exactly the fields the caller provided, with their casted values — so PATCH semantics fall out: omitted keys are untouched, explicit null clears, arrays replace wholesale. Enact.Guardrails mechanically enforces the input-schema invariants (no field defaults, no primary keys, no associations) on first run and in CI.
Errors
Every failure is an %Enact.Error{} with one of five HTTP-shaped types: :invalid (422, carries the changeset), :forbidden (403), :not_found (404), :conflict (409), :internal (500). One renderer in your app handles all of them; actions never invent bespoke error atoms. Reference-resolution failures are field-level "not found" errors indistinguishable from validation failures — and cross-tenant probes are indistinguishable from nonexistent records.
Dry runs and confirmation
Enact.dry_run/3 runs everything up to (not including) execute and returns an %Enact.Preview{} — the exact updates map a real run would persist, the loaded subject, and a digest for confirmation flows:
{:ok, preview} = Projects.update_project_dry_run(params, actor: actor)
# show preview.updates to the user...
{:ok, project} =
  Projects.update_project(params, actor: actor, confirm_digest: preview.digest)
A digest mismatch returns :conflict — "the user confirmed this exact change to this record" is a mechanical guarantee.
Loading a subject
Enact.subject/3 loads the action's subject and authorizes the actor. No body, no write. Use it when the GET needs the record (edit, archive confirmation, create-under-parent):
{:ok, project} = Projects.update_project_subject(params, actor: actor)
Failures are :not_found or :forbidden. An action with no subject raises — use authorized/3 for a new form:
:ok = Projects.create_project_authorized(%{}, actor: actor)
Telemetry
The runner emits [:enact, :action, :run], [:enact, :action, :dry_run], [:enact, :action, :subject], and [:enact, :action, :authorized] events (plus matching :error events) with per-action, per-type metadata — observability and audit trails with zero action-author involvement.
Testing
Enact.Test ships assert_invalid/2, build_ctx/1, and errors_on/1 so host apps don't reinvent them.
Documentation
	Usage Rules — the condensed do's and don'ts for writing actions; sync it into your agent instructions (CLAUDE.md / AGENTS.md) with usage_rules
	Change Detection — how the validation base, presence-gated extraction, and PATCH fidelity actually work, and why force_changes:-style workarounds never appear
	Phoenix Integration — actor/scope wiring, the reference FallbackController and error renderer, Inertia form posts, background jobs, telemetry
	Recipes — worked examples: embedded data end-to-end, flattening embeds into columns, reading resolver assigns, MCP dry-run confirmation flows, empty-string-at-rest columns, partial updates on singular embeds
	Testing Host Applications — copy-paste templates for the host-side test obligations (cross-tenant sweep, PATCH/create matrices, projection completeness, resolver coverage, guardrails in CI)
	Design Specification — the authoritative design, including the rationale for every decision



  

    Changelog

0.1.0 (2026-08-21)
Initial release.
	Enact.run/3, Enact.dry_run/3, Enact.subject/3, and
Enact.authorized/3 — the
load → authorize → cast → validate → resolve → execute → after_commit
pipeline with actor enforcement, the closed error taxonomy, and
telemetry events. subject/3 returns the loaded record; authorized/3
returns :ok. Both are load + authorize only (locator params, no body).
Atom-keyed params are stringified at the boundary (values untouched;
atom+string collision at the same level raises)
	Enact.Action and Enact.InputSchema behaviours; Enact.Actor protocol.
authorize/1 is required (an open write is a written true); optional
callbacks are declared via @optional_callbacks
	Usage rules: params are the invocation payload; persistable fields are
not passed via assigns:
	Phoenix guide: application callers use context one-liners that forward
to Enact.run/3 / dry_run/3 / subject/3 / authorized/3
	Enact.Delegates — opt-in use that generates those one-liners
(create_contact/2, create_contact_dry_run/2,
create_contact_subject/2, create_contact_authorized/2) from
actions: [CreateContact, ...]
	Presence-based change detection: Enact.provided?/2 and Enact.updates/2
	Enact.Resolve — scalar and batch reference resolution with
enumeration-resistant error rendering
	Enact.Validations (check/2, unique/3) and Enact.Guardrails
(mechanical input-schema invariants)
	Enact.Preview with a confirmation digest binding action, mode, locator
params (params keys not in the input schema), and the canonical updates
map; subject is the loaded record for old → new diffs
	Enact.InputSchema.cast_input/4 — casting with JSON API empty-string
semantics derived from field types (keep_empty_strings: option)
	partial_embeds/1 input-schema manifest — partial-object PATCH
semantics for declared embeds_one fields, with presence-faithful
updates, previews, and confirmation digests
	Enact.merged/4 — the result-state view of a partial embed,
shared by merged-result validation rules and the execute-side merge
	Enact.Test helpers for host-app suites, including the
assert_rejects_empty_strings/3 behavioral probe



  

    Enact — Design Specification

A thin, behaviour-based action layer for application write operations, published as a Hex package for use across multiple host applications. This document is the authoritative design; it captures decisions and their rationale so implementation does not relitigate them.
1. Purpose and philosophy
Enact standardizes the shape of every write operation: load → authorize → cast → validate → resolve → execute → after-commit. It is Plug for writes — the value is the uniform pipeline shape, the actor context, and the error taxonomy, not any novel validation or persistence machinery.
Enact orchestrates; Ecto does the work. Validation is Ecto changesets. Input casting is Ecto embedded schemas. Persistence is the host application's existing Ecto schemas and changesets. Enact adds no parallel type system, no validation vocabulary, and no DSL.
Target size: roughly 300–350 lines total (runner, Context, Error, Preview, Resolve, Validations helpers, Guardrails).
Non-goals (decided, do not revisit during implementation)
	No DSL / no macro code generation inside actions or input schemas. use Enact.Action and use Enact.InputSchema set @behaviour and defaults/imports only. Rationale: debuggability, greppability, AI-coding-agent navigability, and reversibility. Optional host-side sugar (use Enact.Delegates) may generate the documented context one-liners; it must not become an action-definition DSL.
	No custom changeset or validation library. Ecto.Changeset is the one and only changeset. Enact.Validations contains a small number of helpers that compose into Ecto pipelines, never replacements for validate_* functions.
	No third-party validation dependency (Peri, Drops, etc.). Revisit only if a census of real actions shows nested input is pervasive enough that per-shape input modules become a tax paid everywhere.
	No OpenAPI generation from input schemas, and no knowledge of any API-documentation library (OpenApiSpex included). The package exposes introspection manifests (fields/1, resolvers/0); host apps hand-write their doc schemas (the public contract should change only by deliberate act) and prevent drift with a host-side reconciliation test against those manifests (§10), not codegen.
	No raising variant (run!), no Ash-style define :create_project code interface, no imperative resolve/2 escape hatch. Context one-liners stay (params, opts) → Enact.run/3 | dry_run/3 | subject/3 | authorized/3; hosts may write them by hand or generate them with use Enact.Delegates.


2. Public API
2.1 Caller contract
# required: actor
Enact.run(ActionModule, params, actor: actor)
# repo override (tests; default from app config)
Enact.run(ActionModule, params, actor: actor, repo: R)

Enact.run(ActionModule, params,
  actor: actor,
  # optional — see §12 (dry-run confirmation)
  confirm_digest: digest
)

# Returns:
{:ok, result}
{:error, %Enact.Error{type: :invalid | :forbidden | :not_found | :conflict | :internal}}

# same options as run/3, minus confirm_digest
Enact.dry_run(ActionModule, params, actor: actor)
# Returns: {:ok, %Enact.Preview{}} | {:error, %Enact.Error{}}   — see §12

# load + authorize; no body, no write. Locator params only.
Enact.subject(ActionModule, params, actor: actor)
# Returns: {:ok, subject} | {:error, %Enact.Error{}}
# no subject → ArgumentError; use authorized/3

Enact.authorized(ActionModule, params, actor: actor)
# Returns: :ok | {:error, %Enact.Error{}}
	The actor is always an explicit, required option. No ambient/process-dictionary context. Every write path is greppable via Enact.run (or use Enact.Delegates at a context that forwards to it) and must answer "as whom?" — actorless writes are unrepresentable by construction (valuable for audit/compliance posture).
	actor: nil always raises ArgumentError (message points at anonymous actors, §2.4): nil is indistinguishable from a forgotten actor — anonymity must be a pattern-matchable value, never an absence. The deliberate collision with Phoenix's current_scope: nil forces public-endpoint callers to construct an explicit anonymous actor at the boundary.
	The actor is opaque to Enact — only the host app's authorize/1 and fetchers read it. Any term works, with no Phoenix dependency; in Phoenix 1.8+ apps the recommended actor is the scope struct (actor: conn.assigns.current_scope), whose role Enact actions naturally inherit.
	run/3, dry_run/3, subject/3, and authorized/3 accept an optional assigns: %{} passthrough merged into ctx.assigns — the documented channel for request metadata (IP, session id) that isn't part of the actor. Resolver-stashed keys are merged after and win on collision. Persistable field values belong in params (what this invocation said) or are stamped in execute/2 from ctx; the passthrough is not a second input channel.
	subject/3 is load + authorize and returns {:ok, subject} or :not_found / :forbidden. The action must have a subject; :no_subject raises ArgumentError (use authorized/3). Pass locator params, not the form body. Do not return %Enact.Context{}.
	authorized/3 is the same prefix and returns :ok or :not_found / :forbidden. For a new form. Still runs load_subject/2 so authorize/1 sees ctx.subject.
	Callers never choose the mode; mode is the action's identity via config/0.
	Same calling convention from controllers, background jobs, tests, IEx. No internal-bypass path.
	Application callers typically go through a context function (Projects.create_project(params, opts)). Those functions are one-liners that forward to run/3 / dry_run/3 / subject/3 / authorized/3. Hosts may write them by hand or generate them with use Enact.Delegates, actions: [CreateProject, ...] (names from the last module segment, underscored). The action module remains the write; the helper is opt-in sugar, not a second API.
	Params keys are stringified at the run/dry_run/subject/authorized boundary (Oban-shaped: atoms at the call site, Plug/JSON strings inside). Values are untouched. Nested plain maps and lists of maps are walked; structs are values and are not walked. Both :id and "id" at the same level raises — the pair is ambiguous. Inside load_subject/2 and ctx.params, match %{"id" => id}, never params[:id].

2.2 The behaviour
Every callback is either pure data or a single-purpose function over (changeset | params, ctx). Maintain this dichotomy.
	Callback	Required	Kind	Purpose
	config/0	no (default [])	data	mode: :create | :patch (default :create), anonymous?: boolean (default false, §2.4)
	input/0	yes	data	Input-schema module, or nil for input-less actions (§4)
	load_subject/2	no (default :no_subject)	function	Fetch the subject — the URL-anchored record the action operates on or within (the updated record in patch mode; the parent in create-under-parent). Always invoked. Default is a no-op; nil → :not_found
	authorize/1	yes	function	(ctx) → boolean | {:error, reason}. Required: a forgotten policy is indistinguishable from an open write. An open write is a written true. false → :forbidden; {:error, reason} → :forbidden carrying reason ({:error, :foo} → %Enact.Error{type: :forbidden, reason: :foo}).
	validate/2	no (default identity)	function	Ordinary changeset pipeline; (changeset, ctx) → changeset. Not invoked for input: nil actions
	resolvers/0	no (default [])	data	Reference-resolution spec (§7)
	execute/2	yes	function	Persist; (changeset, ctx) → {:ok, term} | {:error, term}; runs in transaction
	after_commit/2	no (default :ok)	function	Post-commit side effects (job insertion, analytics); never rolls back

use Enact.Action sets @behaviour Enact.Action and defoverridable defaults for the optional callbacks (config/0, load_subject/2, validate/2, resolvers/0, after_commit/2). That is its entire body. input/0, authorize/1, and execute/2 have no defaults — a missing authorize/1 is a compile warning and a teaching ArgumentError at run/dry_run/subject/authorized.
2.3 Context
%Enact.Context{
  # required, from opts; opaque (struct, scope, or :anonymous)
  actor: term(),
  # filled by load step: updated record (patch) or parent anchor (create)
  subject: struct() | nil,
  # caller params after key stringification (values still raw)
  params: map(),
  repo: module(),
  # from action config
  mode: :create | :patch,
  # resolve step stashes loaded references here
  assigns: %{}
}
2.4 Actors, scopes, and anonymity
Some actions must accept unauthenticated callers (e.g. a public visitor creating a booking through a public link). Design:
	Anonymity is a declared property of the action: config/0 returns anonymous?: true. The security-review question "which write paths accept unauthenticated callers?" is answered by grepping for it — a closed, auditable list. An authenticated actor may still call an anonymous-capable action (anonymous? is a floor, not a partition).
	The Enact.Actor protocol answers anonymous?/1 for any actor term: @fallback_to_any returns false; a built-in impl makes the bare :anonymous atom anonymous (zero-ceremony option for simple apps); host apps add a small impl for their scope struct (%Scope{user: nil} → true), enabling rich anonymous scopes carrying session id / IP for rate limiting — the idiomatic Phoenix 1.8 shape.
	Runner enforcement: actor: nil raises (always, §2.1). Enact.Actor.anonymous?(actor) true → permitted only when the action declares anonymous?: true, otherwise {:error, %Enact.Error{type: :forbidden}} before any pipeline work. Applies identically to dry_run/3, subject/3, and authorized/3.
	Tenancy anchoring without an actor: convention #1 (§9) generalizes — every load and fetcher scopes by a trust anchor: the actor when authenticated, a public-by-construction subject when anonymous (e.g. load_subject/2 fetches the resource by public slug + visibility flag, and all fetchers scope through ctx.subject's tenant, not the actor). Anonymous endpoints are the prime ID-enumeration surface; §7's "not found ≡ not yours" property does real work here.
	Audit/telemetry: events record the anonymous actor affirmatively ("an unauthenticated party did X"), never a null field.

3. Pipeline
Full pipeline: load → authorize → cast → validate → resolve → execute → after_commit
The load step always runs first, in either mode (rationale in invariant 3). The default load_subject/2 returns :no_subject and leaves ctx.subject nil; override it to fetch a subject. authorize/1 takes only ctx (not the changeset), so it runs before cast. subject/3 and authorized/3 are that prefix: load → authorize.
Ordering invariants (structural, not conventional):
	Authorize before cast — unauthorized callers trigger no input work.
	Validate before resolve — cheap gates expensive; garbage input never triggers reference loads.
	Load before authorize and cast — authorize/1 reads ctx.subject; in patch mode the subject also supplies the validation base via from_subject/1 (§5.3).
	Execute inside repo.transaction/1; {:error, reason} from execute rolls back. after_commit runs strictly after successful commit, outside the transaction.

Runner error normalization:
	No cast-stage fast-fail: changeset/3 output (cast, required-ness, base validations) flows into validate/2, and one :invalid is produced after the validate step, in both modes — the caller gets all input errors in a single response. (The runner cannot distinguish cast errors from module validations anyway; check/2 gates the expensive checks.)
	load_subject/2 returning :no_subject (the default) → no subject.
	load_subject/2 returning nil → :not_found.
	authorize/1 false → :forbidden. {:error, reason} → :forbidden carrying reason. {:error, %Enact.Error{}} is passed through.
	Post-validate changeset.valid? == false → :invalid carrying the changeset.
	A %Ecto.Changeset{} error from repo.insert/update (declared constraints) → promoted to :invalid, not :internal.
	Any other execute failure → :internal (see §8 discipline).

Where record-fetching lives: URL-anchored records → load_subject/2 (the subject); body-referenced records → resolvers/0 (§7). Do not pass pre-loaded domain records via the assigns: passthrough: an externally-loaded record escapes trust-anchor enforcement, breaks run/dry_run/subject/authorized parity for callers with no controller (jobs, MCP), and makes provenance unauditable. Actions are self-contained — the extra query is the price, and it's cheap.
4. Input schemas
input/0 returns an embedded-schema input module, or nil for input-less actions.
There is exactly one input shape — do not add others during implementation. Rejected alternatives, and why:
	Flat schemaless types maps (%{name: {:string, required: true}}): the {type, required: true} tuple is an Enact-invented schema vocabulary; modules-only keeps "input schemas are just Ecto" literally true. A dual shape forces a second code path through every subtle part of the runner (cast, base construction, updates/2 key selection, guardrails, reconciliation) — precisely where the PATCH edge cases live — and requires a special runner-applied validate_required rule, whereas with modules required-ness lives in the changeset heads like everything else. The saving is ~8 lines per action, amortized away by shared input modules.
	Inline nested-map recursion in the runner (nested schemas as literal maps, cast recursively): forces manual valid? propagation and changes-internals knowledge into application code; cast_embed on embedded-schema modules does both natively.

input/0 → nil (archive, cancel, resend — subject in the URL, empty body): the runner skips cast and validate, passing an empty changeset through the pipeline; an input-less action's preconditions belong in authorize/1 and its subject checks in load_subject/2. updates/2 returns %{}. Typical config for archive/cancel-style actions: mode: :patch with input: nil and an overridden load_subject/2.
4.1 Input module contract — Enact.InputSchema
With modules as the only input shape, the module's interface is the library's second behavioural contract (after Enact.Action) and is formalized as one:
defmodule Enact.InputSchema do
  @callback changeset(base :: struct(), params :: map(), mode :: atom()) :: Ecto.Changeset.t()
  @callback fields(mode :: atom()) :: [atom()]
  @callback from_subject(subject :: struct()) :: struct()

  # required iff a patch-mode action uses the module
  @optional_callbacks from_subject: 1
end
	use Enact.InputSchema adopts the contract: it sets @behaviour Enact.InputSchema (compile-time signature warnings, dialyzer coverage) and imports cast_input/4 — exactly that, never more. use Ecto.Schema, import Ecto.Changeset, and @primary_key false stay explicit. The general rule: Enact's two behaviours are adopted via use, and each use sets the behaviour and exposes that module's own functions, nothing else. Plain @behaviour + import remains equivalent — guardrails and tests check exports, not the adoption mechanism. The behaviour module's moduledoc is the canonical home for base semantics (why the base exists, what from_subject/1 must guarantee, why no defaults).
	Mode provenance: the runner passes config[:mode] verbatim as the third argument. The union is closed to :create | :patch (matching Context.mode and the config/0 docs). A future custom mode (§13) is mostly an additional changeset/3 head, plus a declaration (e.g. via config) of whether it bases like create (empty struct) or patch (from_subject/1) for the runner's §5.1 branch.

	fields/1 is part of the contract, not just test sugar: it is the introspection surface for mode-specific castable fields (__schema__(:fields) cannot distinguish create-castable from patch-castable). updates/2 key selection (§5.2) and the reconciliation and resolver-coverage tests (§10) read it.
	partial_embeds/1 (optional, default []) declares embeds_one fields with partial-object semantics: updates/2 filters their sub-keys by presence (§5.2), so updates, previews, and confirmation digests carry exactly the provided sub-keys, and execute/2 merges over the subject via Enact.merged/4. embeds_many cannot be declared partial (array merging requires item identity — a different contract); guardrail-enforced. A seeded on_replace: :update alternative was evaluated and deferred (§13).
	from_subject/1 builds the patch-mode validation base (§5.3): an explicit, total projection of the subject into the input representation. Required whenever a patch-mode action uses the module; create-only modules may omit it.
	Enforcement is belt-and-suspenders: the behaviour annotation warns at compile time; the guardrails walk (§9) hard-checks function_exported?(module, :changeset, 3) and fields/1 at first run / in CI, with teaching errors, for modules that skip the annotation.
	cast_input/4 (a function on the behaviour module, imported by input modules) is the casting entry for scalar fields: stock cast plus JSON-API empty-string semantics derived from field types. "" on a non-string field is a cast error rather than a silently-coerced nil (Ecto's forms-era default); empty-ish :string values ("", whitespace-only — the trimmed emptiness test matches Ecto's own default) coalesce to nil, with keep_empty_strings: keeping "" as the value for empty-string-at-rest columns. Casting interprets input and never modifies values — non-empty strings pass through as sent; trimming/hygiene is an explicit changeset-head concern. The option set is closed; required-ness, embeds, defaults, and null-rejection stay where they otherwise live. Stock cast remains legal — Enact.Test.assert_rejects_empty_strings/3 behaviorally verifies the empty-string outcome regardless of mechanism (probing is safe because input modules are dependency-free by contract).
	Deliberate asymmetry — nested item schemas use changeset/2. Items (Milestone etc.) are invoked by cast_embed, not the runner, and are mode-blind: the parent's mode-specific cast list decides whether the embed is reachable at all. Item schemas follow Ecto's native cast_embed convention; top-level input modules follow Enact's /3. Do not "fix" this into a uniform arity. Item schemas take the bare import Enact.InputSchema (no use — they don't adopt the behaviour) and still cast with cast_input/4; since items have no fields/1 manifest, item-level empty-string strictness is a convention rather than a probed guarantee. If an item schema is later promoted to a top-level input for some action (e.g. an "add one item" endpoint), it gains a changeset/3 alongside its changeset/2 — same module, both contracts, no conflict.

4.2 Shared create/patch input modules
Field definitions are written once; per-mode deltas are expressed as data (cast lists / required lists). Convention (illustrative example — a Project resource with nested milestones):
defmodule MyApp.Projects.Inputs.ProjectInput do
  use Ecto.Schema
  # sets @behaviour and imports cast_input (§4.1)
  use Enact.InputSchema
  import Ecto.Changeset

  @primary_key false
  embedded_schema do
    field :name, :string
    field :slug, :string
    # NO defaults — guardrail-enforced
    field :priority, :integer
    # public-facing ID; resolved later
    field :owner_id, :string
    # __MODULE__-qualified: the nested module is defined below, and a bare
    # alias would resolve before its defmodule registers it
    embeds_many :milestones, __MODULE__.Milestone
  end

  @all ~w(name slug priority owner_id)a
  # e.g. slug immutable after create
  @patch @all -- [:slug]
  @required ~w(name slug)a

  # one annotation covers both heads
  @impl true
  def changeset(base, params, :create) do
    base
    |> cast_input(params, @all)
    |> validate_required(@required)
    |> cast_embed(:milestones, required: true)
    |> base_validations()
  end

  def changeset(base, params, :patch) do
    # base makes this correct on PATCH (§5.3)
    base
    |> cast_input(params, @patch)
    |> validate_required(@required)
    |> cast_embed(:milestones)
    |> base_validations()
  end

  @impl true
  def fields(:create), do: @all
  def fields(:patch), do: @patch

  @impl true
  # subject → input vocabulary; embeds never seeded (§5.3)
  def from_subject(project) do
    %__MODULE__{
      name: project.name,
      slug: project.slug,
      priority: project.priority,
      owner_id: PublicIds.encode(:user, project.owner_id)
    }
  end

  # format/bounds/inclusion rules (elided)
  defp base_validations(cs), do: cs

  defmodule Milestone do
    use Ecto.Schema
    import Ecto.Changeset
    # NOTE: bare import, not `use` — item schemas are changeset/2, invoked
    # by cast_embed, and exempt from the InputSchema contract (§4.1
    # asymmetry); they still cast with cast_input for empty-string strictness
    import Enact.InputSchema, only: [cast_input: 3]

    @primary_key false
    embedded_schema do
      field :title, :string
      field :due_on, :date
      field :owner_id, :string
    end

    def changeset(item, params) do
      item
      |> cast_input(params, [:title, :due_on, :owner_id])
      |> validate_required([:title])
    end
  end
end
	The runner calls module.changeset(base, params, ctx.mode).
	base_validations/1 holds rules intrinsic to the payload (format, bounds, inclusion). Action/actor-aware rules stay in the action's validate/2. Dividing line: "true of this data anywhere" vs. "true in this operation." Input modules take no ctx/repo — keep them dependency-free.
	Per-item validations for embeds live in the item schema's own changeset/2; cast_embed invokes them and handles error nesting and valid? propagation natively.
	Nested item modules start nested inside the input module; promote to the context's Inputs namespace on second use. Actions and inputs organize by context (MyApp.Projects.Actions.CreateProject, MyApp.Projects.Inputs.ProjectInput), module names mirroring paths.
	When to split rather than share: if expressing the create/patch delta requires conditionals inside the changeset functions (beyond required-ness and cast lists), the payloads aren't really the same — write separate input modules.
	Escalation for a third variant (admin, API-version): additional changeset head + fields list; mode atom may come from config/0. Do not pre-build.

4.3 Input schema invariants (mechanically enforced — see §9)
	No default: on any field. Omitted fields are excluded from extraction by presence (§5.2), so a schema default never persists — it would only mislead validations into seeing a value the write will not contain. Defaults live in exactly one place: the DB column (preferred) or persistence schema. The host app's API docs document them; the database applies them.
	@primary_key false, recursively. Item IDs cause cast_embed to switch to diff-by-id semantics, silently breaking replace-wholesale PATCH arrays.
	No associations (has_many/belongs_to) — embeds only. An association in an input module means the input/persistence boundary is being blurred.

5. Change detection and the validation base
PATCH requirements: omitted key → untouched; explicit null → clears a scalar field; array key present → replace wholesale (arrays clear with [], never null — cast_embed rejects null on embeds_many, so the contract self-enforces).
Two distinct questions run through every write, and each has exactly one answering mechanism. Keeping them separate is the section's central rule:
	"What did the caller say?" → answered by presence in raw params. Drives extraction/persistence (§5.2).
	"What is the world?" → answered by the validation base (§5.3). Drives what validations see. Never drives extraction.

One mechanism must never answer the other's question: extraction that depends on a diff against the base couples persisted data to base correctness; validations that consult raw params for values re-do casting by hand.
5.1 Casting and the base, by mode
The runner builds the base struct, then calls changeset(base, params, mode):
	Create: base = empty struct (%Input{}). Everything provided casts as a change.
	Patch: base = input_module.from_subject(ctx.subject) — an explicit projection of the loaded subject into the input representation (§5.3). This is why the pipeline loads before casting.

The base exists only so validations see result-state; extraction ignores the changeset's diff entirely (§5.2).
5.2 Extraction — Enact.updates/2
One extractor, both modes: the updates map contains exactly the castable fields the caller provided, with their casted values.
def updates(changeset, ctx) do
  provided =
    changeset.data.__struct__.fields(ctx.mode)
    |> Enum.filter(&provided?(ctx, &1))

  changeset |> apply_changes() |> dump_embeds() |> Map.take(provided)
end
	Key selection is presence-in-params intersected with the mode's castable fields (fields/1) — uniform for scalars and embeds. Provided-but-uncastable keys (e.g. slug on patch) are ignored, consistent with cast/3 dropping unknown params.
	Value correctness is independent of base correctness. For any provided key: a recorded change yields the provided value; no change means the provided value equalled the base, so apply_changes yields it anyway. A wrong projection therefore cannot corrupt persisted data — its blast radius is confined to validation behavior. Omitted keys are excluded by presence and never leak base values into the write.
	The PATCH cases resolve as: omitted → absent from updates → untouched. Explicit null → present with casted value nil → clears. Provided-identical → present with the same value → harmless no-op write (and visible to audit for free). [] on an embed → present with [] → clears the array.
	Never use bare apply_changes/1 output for persistence — it erases omitted-vs-provided.
	Embed values are dumped to plain maps. apply_changes yields input-schema structs, and Ecto.Changeset.cast raises on struct params — so updates/2 recursively unwraps embed structs into plain atom-keyed maps (schema-driven via __schema__(:embeds); scalar structs like dates and decimals stay intact). The updates map feeds persistence changesets and JSON serializers directly; the cast structs remain recoverable from the changeset via apply_changes/1 if ever needed.
	Declared partial embeds (partial_embeds/1, §4.1) are presence-faithful one level down: their dumped maps are filtered to the sub-keys the caller provided (explicit null sub-key → present as nil, a clear; omitted → absent, untouched). This is caller-said interpretation only — the world-merge over the subject's current value stays in execute/2 (via Enact.merged/4), where world-knowledge lives.
	Create correctness falls out: required fields are guaranteed present by validate_required; omitted optionals are absent from updates and fall to DB defaults — client-visible behavior identical to a conventional cast-and-insert.

5.3 The validation base — from_subject/1
In patch mode, validations must see result-state — current values where omitted, new values where provided — so that:
	validate_required works in the patch changeset head: an omitted-but-populated required field passes (base supplies it via get_field); an explicit nil-clear of a required field records a nil change and fails. No special clear-handling helper is needed.
	Cross-field rules read plain Ecto: get_field(cs, :duration_minutes) returns the value the record will have — no per-validation subject-fallback idiom (get_change(...) || subject.field is both bug-prone under nil-clears and an unlabeled inline projection; it must not appear in application code).

The base is produced by from_subject/1 on the input module — part of the Enact.InputSchema contract (§4.1):
@impl true
def from_subject(project) do
  %__MODULE__{
    name: project.name,
    slug: project.slug,
    priority: project.priority,
    # subject → input vocabulary
    owner_id: PublicIds.encode(:user, project.owner_id)
  }

  # embeds intentionally left at structural defaults — never seeded
end
Rules:
	The projection is explicit, owned by the input module, and total over its scalar fields. It is the single home of the subject→input translation (public-ID rendering, renames, representation conversions) — the same mapping the app's serializers maintain, plausibly shared code. Blind struct-copying (Map.take(subject, fields)) is forbidden as an implementation: alignment is a per-module decision to state, not an assumption to inherit.
	Embeds are never seeded — they stay at structural defaults ([]/nil). Array semantics are replace-wholesale; seeding would engage cast_embed's diff-by-identity machinery where no diff exists. Collection-level validations that must run on the []-clear case gate on Enact.provided?/2, and cross-field rules needing current items read ctx.subject directly.
	Completeness is testable (§10): projecting a fully-populated fixture subject must yield a non-nil value for every scalar field. A forgotten field fails CI instead of silently reviving the nil-clear-vs-omitted ambiguity for that field.
	Create mode never calls it; input modules used only by create actions may omit it (guardrail-checked only when a patch-mode action references the module, §9).

5.4 Enact.provided?/2
Enact.provided?(ctx, key_or_path) — providedness in raw params, the reification of "what did the caller say?" at any depth. It lives on the root module, not Enact.Validations, because its consumers span the architecture: updates/2 (extraction), validation gating, and host execute interpreters.
	provided?(ctx, :items) — top-level key presence (string-or-atom keyed).
	provided?(ctx, [:items, 2, :quantity]) — path form: atoms descend into maps, integers index into lists. Anything unreachable (missing key, out-of-range index, non-map element) returns false; the function never raises and never converts strings to atoms — hand-rolled versions using String.to_existing_atom/1 on client-supplied keys crash on unknown input, which is why the library owns this primitive.

Used by updates/2 for key selection, by collection-level validations that must run on the []-clear case (which get_change-gating would skip), and by host execute interpreters that need per-index sub-field providedness (op-batch endpoints implementing per-op merge semantics).
6. Validation
All validation lives in changeset pipelines: the action's validate/2 for operation-specific rules, the input module's base_validations for payload-intrinsic rules, and item changeset/2s for per-item rules. Input schemas declare shape only (fields, types, embeds); required-ness lives in the mode-specific changeset heads. Rationale: co-dependent and conditional validations are miserable in any schema vocabulary and trivial as functions; Ecto's own schema/changeset split is the precedent.
Patterns:
	Cheap gates expensive: Enact.Validations.check/2 — no-ops if changeset.valid? is already false; otherwise applies the given function. All DB-backed checks go through it.
	Collection-level rules (cross-item consistency, at-least-one, max-N): parent pipeline; materialize via apply_changes (values, not diffs); attach errors to the parent key; run after item validity is established.
	Result-state reads: with the base in place (§5.3), get_field/2 is the standard way to read "the value the record will have" — cross-field rules use it directly. Enact.provided?/2 gates rules that must run only when the caller touched a key (including []-clears) — the explicit module prefix usefully marks raw-params reads, the sanctioned exception to "validations read the changeset." The get_change(...) || ctx.subject.field fallback idiom is forbidden in application code (§5.3).
	Enact.Validations.unique/3: scoped uniqueness for input changesets (scope:, repo:, query:, except: opts); skips when the field has no change. except: excludes the current row on PATCH (struct, id, or keyword). Soft-deletes stay on :query.
	Enact.merged/4: the result-state view of a partial embed (§4.1 partial_embeds/1) — each sub-key reads the caller's casted value where provided (explicit nulls read as clears) and the subject's current value where not; whole-object nulls read as all-nil; keys derive from the schema by default. Lives on the root module because its consumers span validate (merged-result rules) and execute (it is the merge — one shared definition). The presence-gated, sanctioned sibling of the forbidden change-gated fallback.

7. Reference resolution — resolvers/0 + Enact.Resolve
Payload references (public-facing IDs like usr_XXXX) get their own pipeline step. Resolution failures are field-level :invalid errors ("not found" on the field), never :not_found — 404 belongs to the URL subject; and "exists but not yours" must be indistinguishable from "doesn't exist" (enumeration resistance). Genuine capability denials stay in authorize/1.
Spec is declarative data (consistent with the data-callback rule; enables the introspection tests in §10):
def resolvers do
  [
    # scalar
    owner: {:owner_id, &fetch_owner/2},
    # path form → batch
    milestone_owners: {[:milestones, :owner_id], &fetch_milestone_owners/2}
  ]
end
Scalar fetcher contract: (public_id, ctx) → {:ok, struct} | :error | {:error, message}. Bare :error renders the generic "not found" field error; {:error, message} renders a precise message on the same field through the same propagation path. Skipped when the field has no change (patch composes free: untouched reference survives; provided reference re-resolves and re-authorizes).
Error precision — the trust-anchor rule. Collapse is mandatory outside the trust anchor; precision is permitted inside it:
	Missing vs. wrong-tenant must be indistinguishable (both → bare :error → "not found"). If they render differently, probing IDs reveals which exist — the enumeration-resistance property.
	Deleted / permission-denied within the caller's own tenant may be precise ({:error, "has been deactivated"}, {:error, "cannot be assigned by your role"}). The caller can legitimately know these records exist; generic "not found" here is bad UX with zero security payoff.
	Safety comes from check ordering inside the fetcher: scope by the trust anchor first; emit precise messages only about records the anchor-scoped query returned. (Residual convention, §9; the cross-tenant sweep verifies foreign references produce only the generic message.)

Path/batch fetcher contract: (ids_list, ctx) → %{public_id => struct | {:error, message}}. Absent ids render the generic "not found"; {:error, message} values render precise per-item messages (same trust-anchor rule applies). Helper mechanics (library-owned; the manual nested-changeset surgery is acceptable here because it's ~10 tested library lines, not application code):
	Collect unique non-nil field changes across item changesets of the embed.
	One fetcher call (batching: N items ≠ N queries; scoping written once; duplicates deduped).
	Items whose id is absent from the result map: add_error on the item changeset, splice the list back into parent changes, explicitly mark parent invalid. Errors render at correct indices via the same traverse_errors path as cast_embed failures.
	Success: stash in assigns — scalar as the struct (ctx.assigns.owner), batch as the lookup map keyed by public id (ctx.assigns.milestone_owners; survives duplicates/reordering, makes the execute-side join a map read).
	Nil item-ids are skipped (mirror scalar behavior); if the id is required, item-level validate_required catches it pre-resolve.
	Implement paths one level deep only; deeper nesting is an API-shape smell until proven otherwise.

Propagation summary: resolution failures are ordinary field errors in the same changeset as validation errors — collected without short-circuiting (all bad references surface in one round trip), wrapped as Enact.Error.invalid(changeset), rendered via the host app's traverse_errors/2 path. To the API consumer a resolution failure is shape-identical to a validation failure: same 422, envelope, and field addressing (per-index nesting included). Resolve tags its errors with metadata (add_error(cs, field, msg, validation: :resolution)) so renderers or stable API error codes can distinguish input-format errors from reference errors without string matching; message text and i18n remain host-app renderer concerns.
execute/2 translates public→internal ids by reading assigns (e.g. ctx.assigns.owner.id). Manual splicing into the updates map is acceptable for now; a put: option on the spec is the second-use extraction if it proliferates.
8. Errors — Enact.Error
defstruct [:type, :changeset, :reason, meta: %{}]
# type: :invalid | :forbidden | :not_found | :conflict | :internal
# Constructors: invalid/1 (changeset), forbidden/0-1, not_found/0-1, conflict/0-2, internal/1
	Closed taxonomy, HTTP-shaped: invalid→422, forbidden→403, not_found→404, conflict→409, internal→500. No bespoke error atoms from actions — the renderer must never grow a default clause.
	reason is a stable term (atom, not a user-facing string) for logs, telemetry, and host rendering. Do not echo it wholesale. :invalid is the only type that carries caller-visible detail by default (the changeset — safe: it describes the caller's own input). The default renderer maps type to generic copy. The host may translate a closed set of host-owned reasons into copy, typically :forbidden from authorize/1. Do not use :not_found reasons to reveal that a record exists. Rendering = one ErrorRenderer using traverse_errors/2; handles nested/indexed embed errors with zero per-action knowledge; it is the API-versioning seam.
	:conflict for optimistic/temporal races (resource claimed between validation and insert, stale_error_field). Input was fine; the world changed.
	404/403 collapse is renderer policy (defense in depth; tenant-scoped load_subject/2 mostly produces :not_found for cross-tenant probes anyway). Internally keep both types — different bugs.
	:internal is a bug bucket. Every production occurrence is either a bug or a missing promotion to a real type. Runner auto-promotes constraint-error changesets from repo failures to :invalid.
	Telemetry: the runner emits, per-action, per-type, with zero action-author involvement:	[:enact, :action, :run] / [:enact, :action, :run, :error] — the run event fires after a successful commit but before after_commit/2, so a raising side effect cannot suppress the audit record of a committed write
	[:enact, :action, :dry_run] / [:enact, :action, :dry_run, :error]
	[:enact, :action, :subject] / [:enact, :action, :subject, :error]
	[:enact, :action, :authorized] / [:enact, :action, :authorized, :error]
Error events carry type: (Enact.Error type). Distinct events so form GETs, previews, and executions are never conflated. A dry run or subject/authorized check is still an authorization-relevant event and should be auditable as one.


	meta for machine-readable extras (retry_after, stable error codes) only.

9. Guardrails — Enact.Guardrails
Principle: every "just don't do X" rule that is mechanically detectable gets detected and raised — conventions upgrade to invariants.
assert_valid_input_schema!/1 walks an input module recursively (via __schema__(:embeds) / __schema__(:embed, name).related, with a cycle guard for self-referential embeds) and raises with teaching error messages on:
	Any scalar field with a non-nil default in struct(module) (embed fields excluded — their structural []/nil defaults are fine).
	__schema__(:primary_key) != [] at any level (the nested-item level is where IDs sneak in).
	__schema__(:associations) != [] — embeds only.
	Top-level modules only: missing changeset/3 or fields/1 exports, or missing from_subject/1 on a module referenced by any patch-mode action (the Enact.InputSchema contract, §4.1/§5.3) — teaching errors pointing at the behaviour docs. Nested item modules are exempt (they implement changeset/2 for cast_embed; §4.1 asymmetry note).

Invocation: memoized first-run check, plus a CI test that calls it on every action's input module explicitly (avoids @after_compile ordering subtleties while keeping compile-adjacent feedback).
Residual conventions (not mechanically checkable; mitigate with the §10 cross-tenant test + greppable single locations):
	load_subject/2 and every fetcher must scope by a trust anchor — the actor/tenant when authenticated; a public-by-construction subject for anonymous?: true actions (§2.4).
	Fetchers check the trust anchor first and emit precise error messages only about records the anchor-scoped query returned (§7).
	Writes go through Enact.run — no direct-Repo context functions (social + optional Credo rule).
	Optional scalar columns are nullable with no default — NULL is the single representation of empty, aligning storage, ctx.subject, JSON null, and stock cast coalescing (the sibling of §4.3's "defaults live in the DB"). NOT NULL DEFAULT '' columns force "" into the input domain and require per-field ""-preserving casts; reserve them for fields where empty-string is genuinely distinct from absent.

10. Required tests (part of the definition of done)
	Doc-schema reconciliation (host-app test): the package's role ends at the introspection manifests (fields/1, resolvers/0); it knows nothing of OpenApiSpex or any other documentation library and must never grow such a dependency (§1 non-goals). Host apps write a drift test zipping Input.fields(mode) against their API-doc source of truth — for OpenApiSpex, each request schema's properties (extendable to types/required).	Resolver coverage (host-app test, package manifests only): every *_id input field has a resolvers/0 entry, with an explicit per-action allowlist for legitimately opaque _id fields (external references, idempotency keys) — exceptions stay visible instead of weakening the rule. Catches "added reference, forgot resolver," which otherwise sends a raw public-id string to persistence.


	Cross-tenant sweep: every action run with a tenant-A actor against tenant-B subject and references → :not_found / field errors, and foreign-reference field errors carry only the generic "not found" message (never a precise one). Enumerates reference fields from resolvers/0 specs.	Anonymous variants: every anonymous?: true action run as an anonymous actor against references outside the subject's tenant → field errors (fetchers must scope through the public subject, not the actor).


	PATCH matrix per patch action: omitted key untouched; explicit nil clears scalar; explicit nil on a required field → :invalid; omitted required-but-populated field passes validate_required; [] clears array (presence-gated validations still run); provided-identical persists as a harmless no-op write; provided reference re-resolves; absent reference survives.
	Create matrix: omitted optional falls to DB default; explicit nil on required field fails validate_required.
	Guardrails: all input modules pass assert_valid_input_schema!; a fixture module with a default/PK/association raises with the expected message.
	Projection completeness (host-app, per patch-mode input module): from_subject/1 on a fully-populated fixture subject yields a non-nil value for every scalar field, and leaves embeds at structural defaults — a forgotten or mistranslated field fails CI instead of silently degrading validation behavior for that field.
	Error taxonomy: each failure class maps to its Enact.Error type; reason is not echoed wholesale; nested resolution errors render at correct indices.
	Test helper: assert_invalid(result, on: field).

11. Module inventory
	Module	Contents	~Lines
	Enact	run/3, dry_run/3, subject/3, authorized/3, pipeline steps, updates/2, path-capable provided?/2, merged/4, digest, transaction/error normalization, telemetry	120
	Enact.Action	behaviour + __using__ defaults	40
	Enact.Context	struct	15
	Enact.Actor	protocol: anonymous?/1 + Any/Atom impls	15
	Enact.InputSchema	behaviour: changeset/3, fields/1, from_subject/1, partial_embeds/1 + cast_input/4 + moduledoc	75
	Enact.Error	struct + constructors	30
	Enact.Preview	struct + canonical digest encoding	20
	Enact.Resolve	scalar + path/batch resolution, item-error splicing	60
	Enact.Validations	changeset-pipeline combinators: check/2, unique/3	30
	Enact.Guardrails	recursive input-schema assertions	40
	Enact.Test	assert_invalid/2, assert_rejects_empty_strings/3, ctx builder, shared test support	60
	Enact.Delegates	opt-in use that generates context run / dry_run / subject / authorized one-liners from action modules	40

Packaging: ships as a Hex package from the start, so it can be shared across multiple host applications.
	Dependencies: ecto (core only — no ecto_sql requirement; changesets ship without database machinery). telemetry for the runner events. Nothing else.
	The repo is injected per call (repo: option) or set via host-app config (config :enact, repo: MyApp.Repo) — the package itself never owns a repo.
	Versioning: start at 0.x and treat the behaviours (Enact.Action, Enact.InputSchema), the Enact.Actor protocol, the Enact.Error and Enact.Preview shapes, and the Enact module functions (run/3, dry_run/3, subject/3, authorized/3, updates/2, provided?/2) as the compatibility surface across consuming apps. Because multiple codebases consume it, breaking changes to callback signatures or the error taxonomy are the expensive kind — batch them.
	No host-app assumptions: no auth coupling (fetchers own authorization), no HTTP/Phoenix dependency (the ErrorRenderer lives in the host; scope structs work as actors via opacity + Enact.Actor), no JSON library, no API-documentation tooling (§10).
	The §10 tests split accordingly: pipeline/guardrail/resolve mechanics are package tests; reconciliation, cross-tenant sweeps, and the PATCH/create matrices are host-app tests (they depend on real actions and schemas). Ship the assert_invalid helper and any test support in an Enact.Test module so host apps don't reinvent it.

12. Dry run / confirmation flow — Enact.dry_run/3 + Enact.Preview
Motivation: agent-facing surfaces (e.g. MCP tools with a confirmation step) need to take user input, validate it fully, and reflect the casted/normalized changes back for confirmation before anything persists.
The pipeline is already staged for this: every step before execute is side-effect free (validate/resolve perform DB reads only; the transaction opens at persist). dry_run/3 runs load → authorize → cast → validate → resolve, then stops.
Enact.dry_run(ActionModule, params, actor: actor)

{:ok,
 %Enact.Preview{
   action: ActionModule,
   mode: :patch,
   # Enact.updates/2 output — casted, normalized, validated
   updates: %{...},
   # the loaded URL-anchored record (nil when there is no subject)
   subject: %Project{...},
   # names of resolvers that succeeded — never the structs
   resolved: [:owner],
   # hash binding action, mode, locator params, and the canonical updates map
   digest: "sha256:..."
 }}
# identical error surface to run/3
| {:error, %Enact.Error{}}
Design decisions:
	Distinct %Enact.Preview{} struct — callers must be structurally unable to confuse "validated" with "executed". Never a flag on the normal result.
	Preview carries updates/2 output, not the changeset. It is the canonical, post-normalization "what will be persisted" map — the single definition of the diff shared by validation, persistence, and preview. What the user confirms is definitionally what executes.
	Confirmation digest. dry_run digests the action module, the mode, leftover locator params (params keys not in the input schema's fields/1), and the canonically-encoded updates map together (deterministic encoding — sorted keys, stable struct/date encoding; Elixir map ordering is not sufficient). Folding locators in means a digest minted for record A never confirms the same change to record B, and input-less actions (whose updates are always %{}) don't collapse across subjects. Folding action and mode in means a digest minted for one action or mode never confirms another. run/3 accepts optional confirm_digest:, recomputes post-validation, and returns :conflict on mismatch: "the user confirmed this exact change to this record" becomes a mechanical guarantee across the confirmation gap. Non-confirmation callers never see it.
	No reservation semantics (non-goal). A preview is not a promise; the confirming run/3 re-executes the full pipeline, and races surface as :invalid/:conflict normally. If a domain needs "hold this resource during confirmation", model it as an explicit domain action (a hold with a TTL), never as dry-run machinery.
	Resolved references leak nothing. The preview lists resolver names that succeeded; loaded structs stay in ctx.assigns and never reach the caller (field-leakage risk toward agents). If confirmation UX needs display info ("assigning to Jane Doe"), that is host-app rendering; a preview/2 option on resolver specs is a deferred second-use extraction (§13).
	Preview carries the loaded subject. subject is the record load_subject/2 returned (the updated record in patch mode; the parent in create-under-parent; nil when there is no subject). Host apps render old → new diffs by comparing updates against it. The digest binds leftover locator params, not the loaded struct.
	Patch previews carry the provided keys (updates/2 semantics, §5.2).
	Authorization runs in dry runs (don't preview what you can't do), and dry runs emit distinct telemetry (§8).

Tests (additions to §10): dry_run performs no writes (assert on the Repo); preview updates equals what a subsequent run persists for identical params; preview subject is the loaded record (nil when there is none); digest mismatch returns :conflict; a digest minted for one locator never confirms another; digest match with changed world state still re-validates; preview never contains resolved structs.
13. Deferred (second-use rule — do not implement now)
	Code-interface sugar (Domain.create_project/2 via define)
	run! raising variant
	Imperative resolve/2 escape hatch
	put: option on resolver specs (auto-splice internal ids into updates)
	preview/2 option on resolver specs (safe display fields for confirmation UX)
	validate_change_if_present/3 helper
	Shared resolvers module (extract at second duplicated fetcher)
	Third input mode (admin/API-version variants)
	Resolver paths deeper than one level
	Mode-aware base_validations/2
	DSL frontend / third-party validator adoption (revisit triggers documented in §1)
	Seeded on_replace: :update embeds — an evaluated alternative to partial_embeds/1 (§4.1), recorded so the reasoning survives. Design: from_subject/1 seeds the current embeds_one value and the schema declares on_replace: :update, so Ecto casts partial params over current data. What it wins: result-state validation natively (item-level validate_required works, plain get_field returns the merged object, no Enact.merged/4 call), and zero execute-side merge (apply_changes already yields the object to persist). Why partial_embeds/1 was chosen instead: (1) the updates map would carry result-state for these embeds while remaining delta everywhere else — mixed per-key semantics, against the uniform "updates = what the caller said" contract; (2) the digest would bind resulting state rather than the caller's instruction, which is a genuine semantic fork: delta-binding lets concurrent changes to untouched sub-keys pass (matching the no-reservation stance, fewer spurious conflicts in agent confirmation flows), resulting-binding turns them into :conflict (optimistic concurrency on the whole object); (3) the display trade mirrors rather than disappears — resulting state shown means the delta must be diffed host-side for "what changed" display. The validation advantage is largely neutralized by Enact.merged/4 (one call vs. native get_field). Open question before any adoption: whether a whole-object null-clear is expressible under on_replace: :update (the nil-cast path routes through on_replace; verify against Ecto source). Trigger: real embeds where resulting-state confirmation and item-level required-ness matter more than delta semantics. Would coexist with partial_embeds/1 as a second declared per-embed contract, not replace it. (Seeding embeds_many remains rejected outright: PK-less items give the differ nothing to match, so every seeded item routes through on_replace for no benefit.)



  

    Enact usage rules

Rules for writing application code in a project that uses Enact. Enact standardizes every write operation as an action module run through load → authorize → cast → validate → resolve → execute → after_commit. Enact orchestrates; Ecto does the work — there is no DSL and no custom validation vocabulary.
Calling actions
	Every write goes through an action via Enact.run/3. Never write via Repo.insert/update/delete. Application callers (controllers, LiveViews, jobs) typically go through a context one-liner that only forwards to Enact.run/3 / dry_run/3 / subject/3 / authorized/3 — see the Phoenix guide. Those one-liners may be handwritten or generated with use Enact.Delegates, actions: [CreateProject, ...]. Action tests and IEx may call Enact.run/3 directly.
	Callers may pass atom- or string-keyed maps. The runner stringifies keys before any callback runs, so load_subject/2 and ctx.params always see strings. Match %{"id" => id}, never params[:id]. Values are not rewritten.
	Params are the invocation payload, not "what a human typed." Jobs and :system are callers. A value this run is saying — something that will be persisted and previewed — belongs in params on an action whose authorize/1 allows that caller.
	actor: is required and actor: nil raises. For unauthenticated callers pass an explicit anonymous actor (:anonymous, or a scope struct whose Enact.Actor impl returns true), and only against actions declaring anonymous?: true in config/0.
	Pass request metadata (IP, session id) via assigns: %{}. Never pass pre-loaded domain records or persistable fields through assigns: — records are fetched by load_subject/2 / resolvers/0; persistable fields smuggled here skip cast, updates/2, preview, and the digest. Actions are self-contained; the extra query is the price.
	The same calling convention applies from controllers, background jobs, tests, and IEx. There is no internal-bypass path.
	For confirmation flows: the context's *_dry_run one-liner (or Enact.dry_run/3) returns an %Enact.Preview{}; pass preview.digest back as confirm_digest:. A mismatch returns :conflict. Compare preview.updates against preview.subject for old → new diffs. Resolved structs stay out of the preview (resolved is names only).
	For the GET that needs the action's record (edit, archive confirmation, create-under-parent): Enact.subject/3 (or *_subject). Pass locator params only. Returns {:ok, subject} or :not_found / :forbidden. An action with no subject raises — use authorized/3.
	For a new form: Enact.authorized/3 (or *_authorized). Returns :ok or :forbidden / :not_found. Does not return a record.

Organizing modules
Group actions and inputs by context, in actions/ and inputs/ subdirectories, with module names mirroring paths:
lib/my_app/projects/
  projects.ex                 # context: reads, fetch helpers, write one-liners
  project.ex                  # persistence schema
  inputs/project_input.ex     # MyApp.Projects.Inputs.ProjectInput
  actions/create_project.ex   # MyApp.Projects.Actions.CreateProject
  actions/update_project.ex
  actions/archive_project.ex
	Input modules are shared per resource (one ProjectInput serving both create and patch), so they sit beside the actions that use them.
	The context module keeps reads, whatever load_subject/2 delegates to, and one-liner write delegates (def create_project(params, opts), do: Enact.run(CreateProject, params, opts), or use Enact.Delegates, actions: [CreateProject]). Those bodies only forward — no param reshaping, no persistable fields stamped in. The action is the write.
	Resolver fetchers start as private functions in the action that declares them; extract a shared module only at the second duplicated fetcher.
	Nested item schemas start nested inside their input module; promote to inputs/<item>_input.ex in the same context on second use.

Writing an action
defmodule MyApp.Projects.Actions.UpdateProject do
  use Enact.Action

  alias MyApp.Projects
  alias MyApp.Projects.Inputs.ProjectInput
  alias MyApp.Projects.Project

  @impl Enact.Action
  def config, do: [mode: :patch]

  @impl Enact.Action
  def input, do: ProjectInput

  @impl Enact.Action
  def load_subject(%{"id" => id}, ctx), do: Projects.get_project(ctx.actor, id)

  @impl Enact.Action
  def authorize(ctx), do: MyApp.Policy.can?(ctx.actor, :update, ctx.subject)

  @impl Enact.Action
  def execute(changeset, ctx) do
    updates = Enact.updates(changeset, ctx)

    ctx.subject
    |> Project.changeset(updates)
    |> ctx.repo.update()
  end
end
	config/0, input/0, and resolvers/0 return pure data. load_subject/2, authorize/1, validate/2, execute/2, after_commit/2 are single-purpose functions. Keep that dichotomy.
	authorize/1 is required. Return true, false, or {:error, reason}. false becomes {:error, %Enact.Error{type: :forbidden}}; {:error, :foo} becomes {:error, %Enact.Error{type: :forbidden, reason: :foo}}. Use a host-owned atom for reason when the renderer should vary the 403 copy. Do not echo reason wholesale; do not put user-facing strings in it. An open write is a written true (def authorize(_ctx), do: true), never an omitted callback.
	The URL-anchored record is the subject → override load_subject/2 (the updated record in patch mode; the parent in create-under-parent). The default is a no-op (:no_subject); nil means :not_found. Body-referenced public ids → resolvers/0. No other fetching channel.
	load_subject/2 and every resolver fetcher must scope by a trust anchor: the actor's tenant when authenticated; a public-by-construction subject for anonymous?: true actions. Returning nil from load_subject/2 produces :not_found — cross-tenant probes must be indistinguishable from nonexistent records.
	Never invent error atoms. The taxonomy is closed: :invalid, :forbidden, :not_found, :conflict, :internal. To signal a race from execute/2, return {:error, Enact.Error.conflict(:reason)}.
	In execute/2: build the write from Enact.updates(changeset, ctx) — never from bare apply_changes/1 (it erases omitted-vs-provided). Translate public ids by reading ctx.assigns (e.g. ctx.assigns.owner.id). The updates map is persistence-ready: embeds arrive as plain maps, so feed it straight to your persistence changeset. Declare DB constraints; the runner promotes constraint-error changesets to :invalid.
	Values the action decides (tenant, parent id, default permissions) are stamped in execute/2 from ctx.actor, ctx.subject, or policy — not passed in. Do not give one field two sources (params for users, assigns for the system). Split the action or the input module when the payloads differ.
	after_commit/2 is for post-commit side effects only (job insertion, analytics). It runs outside the transaction and can never roll back.
	Archive/cancel/resend-style actions: mode: :patch, input: nil plus an overridden load_subject/2 — preconditions go in authorize/1, subject checks in load_subject/2.

Input schemas
	An input module is a plain use Ecto.Schema + embedded_schema module that adds use Enact.InputSchema (sets the behaviour and imports cast_input/4 — nothing more), implementing changeset/3 (one head per mode), fields/1, and — iff any patch-mode action uses it — from_subject/1.
	Cast scalar fields with cast_input/4, not stock cast: it derives empty-string handling from field types — "" on a non-string field is a cast error instead of a silently-coerced nil; empty-ish :string values ("", whitespace-only) coalesce to nil, and non-empty values pass through as sent (casting never modifies values — trimming is an explicit changeset-head concern if wanted). One option: keep_empty_strings: for NOT NULL DEFAULT '' columns. Cast embeds with cast_embed/3 as usual.
	@primary_key false at every nesting level. No default: on any field. No associations — embeds only. (Enact.Guardrails raises on all three at first run.)
	Required-ness lives in the changeset heads via validate_required, never in the schema. Per-mode differences are expressed as data (cast lists, required lists) — if you need conditionals inside the changeset heads, split into separate input modules.
	fields/1 must list the mode's castable fields including embed names — Enact.updates/2 and the host test suite read it.
	Nested item schemas implement Ecto's native changeset/2 (invoked by cast_embed) and do not adopt the behaviour — take the bare import Enact.InputSchema and still cast with cast_input/4. This asymmetry is deliberate. Note the strictness probe covers top-level fields only (item schemas have no fields/1 manifest), so item-level strictness is a convention, not a probed guarantee.
	Embeds are replace-wholesale by default. Declare embeds_one fields that accept partial objects in the optional partial_embeds/1 manifest — Enact.updates/2 then carries only the provided sub-keys, and execute/2 merges over the subject via Enact.merged/4 (the same function merged-result validations use). embeds_many cannot be partial. Worked example: recipe 6.
	from_subject/1 is an explicit projection of the subject into the input vocabulary (public-id rendering, renames), total over scalar fields. Never seed embeds — leave them at structural defaults. Never implement it as a blind Map.take.
	Pair with the data-layer convention: optional scalar columns are nullable with no default — NULL is the single representation of empty, so empty strings coalescing to nil is correct and an explicit null is just a clear. Reserve NOT NULL DEFAULT '' for fields where "" is genuinely meaningful as distinct from absent; list those in cast_input/4's keep_empty_strings: — see the Change Detection guide.

Validation
	Payload-intrinsic rules (format, bounds, inclusion) → the input module's own pipeline. Operation- and actor-aware rules → the action's validate/2. Dividing line: "true of this data anywhere" vs. "true in this operation."
	Read result-state with get_field/2 — the patch base guarantees it returns the value the record will have. Forbidden: get_change(cs, :field) || ctx.subject.field.
	Wrap every DB-backed check in Enact.Validations.check/2 (no-ops when the changeset is already invalid). Use Enact.Validations.unique/3 for scoped uniqueness pre-flight. On PATCH pass except: ctx.subject. Filter soft-deletes on :query.
	Gate rules that must run only when the caller touched a key — including []-clears, which get_change-gating would miss — with Enact.provided?(ctx, key_or_path). That is the only sanctioned raw-params read in a validation.
	For rules about the merged result of a partial embed, build the result-state view with Enact.merged(changeset, ctx, :embed) — each sub-key reads the caller's value where provided (explicit nulls read as clears) and the subject's current value where not.

PATCH semantics
Omitted key → untouched. Explicit null → clears the scalar. Array key present → replaces wholesale; [] clears (arrays never clear with null). Enact.updates/2 implements all of this via presence-in-params — trust it rather than hand-rolling merge logic in execute/2. (Mechanics explained in the Change Detection guide, guides/change-detection.md.)
Resolvers
	Scalar: name: {:field, fetcher} where fetcher.(public_id, ctx) returns {:ok, struct} | :error | {:error, message}. Batch over an embeds_many: name: {[:embed, :item_field], fetcher} where fetcher.(ids, ctx) returns %{public_id => struct | {:error, message}}.

	Trust-anchor rule: scope the query by the trust anchor first. Missing and wrong-tenant must both produce the generic :error → "not found". Precise messages ({:error, "has been deactivated"}) are permitted only for records the anchor-scoped query returned.
	Every *_id payload field gets a resolver entry (or an explicit allowlist entry in the host coverage test). Forgetting one sends a raw public-id string to persistence.
	Resolution failures render as field-level :invalid errors, never :not_found.

Errors
	One renderer handles the closed taxonomy; it must never need a default clause for type. Default copy is generic by type. You may match host-owned reason atoms (usually :forbidden) to vary the message; do not echo reason wholesale. The only type that carries caller-visible detail by default is :invalid via the changeset.

Testing
	import Enact.Test for assert_invalid/2, build_ctx/1, errors_on/1.
	Host apps own the tests that depend on their actions, schemas, and tenancy: guardrails-in-CI, the cross-tenant sweep, the PATCH/create matrices, projection completeness, and resolver coverage. See the "Testing Host Applications" guide for templates.

Worked examples
End-to-end samples following these conventions — embedded data with batch resolution, flattening embeds into columns, reading resolver assigns in execute, MCP dry-run confirmation flows, empty-string-at-rest columns, partial updates on singular embeds — live in the Recipes guide (guides/recipes.md).


  

    Change Detection

This guide explains how Enact determines what a write contains, and why common Ecto PATCH workarounds (force_changes:, subject-fallback reads, manual merge logic) are not needed.
The two questions
Every write answers two separate questions, each with its own mechanism:
	What did the caller provide? Answered by key presence in the raw params, through Enact.provided?/2 and Enact.updates/2. This determines what is persisted.
	What is the current state? Answered by the validation base — the struct the changeset is cast over. This determines what validations see. It never affects what is persisted.

The two mechanisms stay separate. If extraction depended on a diff against the base, persisted data would depend on base correctness. If validations read raw params for values, they would repeat casting by hand.
The validation base
The runner builds a base struct and calls the input module's changeset(base, params, mode):
	Create: the base is the empty struct (%ProjectInput{}). Every provided field casts as a change.
	Patch: the base is from_subject(ctx.subject) — the input struct populated with the record's current values, translated into the input representation (public IDs rendered, fields renamed). This is why the pipeline loads the subject before casting.

With the base in place, standard Ecto functions behave correctly on PATCH:
	validate_required/2 works without modification. A required field that is omitted but populated on the record passes, because the base supplies the value through get_field. An explicit nil-clear records a nil change and fails.
	Cross-field rules read get_field/2 and see the value the record will have after the write: the current value where omitted, the new value where provided.

Two rules constrain the base:
	Only scalar fields are seeded. Embeds stay at their structural defaults ([] or nil), so provided arrays cast as inserts rather than engaging cast_embed's diff-by-identity behavior.
	The base affects validation only. Extraction ignores the changeset diff, so an incorrect from_subject/1 projection cannot corrupt persisted data. Projection mistakes affect validation behavior only, and the projection-completeness test (see the Testing guide) catches them in CI.

Extraction
Enact.updates/2 produces the map that execute/2 persists:
provided = module.fields(ctx.mode) |> Enum.filter(&Enact.provided?(ctx, &1))

changeset
|> Ecto.Changeset.apply_changes()
|> dump_embeds(module)   # embed structs → plain maps, recursively
|> Map.take(provided)
Key selection is presence-in-params intersected with the mode's castable fields (fields/1). Extraction does not read the change list. Values come from apply_changes/1, with embed structs dumped to plain, atom-keyed maps. The dump is schema-driven, so scalar structs such as Date and Decimal pass through unchanged. The resulting map can be passed directly to persistence changesets and JSON encoders.
The updates map is atom-keyed at every level, and every atom comes from a schema definition. Client params never create atoms: provided?/2 matches string keys by converting the schema atom to a string, and cast drops unknown keys. When passing the map to Ecto functions, do not merge string-keyed entries into it — Ecto rejects mixed-key maps.
For any provided key, one of two cases holds: a change exists, and apply_changes yields the casted value; or no change exists because the provided value equals the base value, and apply_changes yields that same value. In both cases the updates map contains what the caller provided.
Embeds declared in the input module's partial_embeds/1 manifest extend presence one level down: their dumped maps contain only the sub-keys the caller provided, with the same omitted-vs-null fidelity as top-level fields. See recipe 6 in the Recipes guide for the merge pattern.
"Equals" here is Ecto's semantic equality (Ecto.Type.equal?), not structural equality. For types with multiple representations of one value — Decimal 1.0 versus 1.00 — a provided value semantically equal to the base records no change, and updates carry the base's representation. The persisted value is semantically what the caller sent; only its formatting can differ, and it is consistent between a dry run and the confirming run.
The PATCH cases resolve as follows:
	Caller sends	Change recorded?	In updates?	Effect
	key omitted	no	no	untouched
	null (field populated)	yes, to nil	yes, as nil	clears
	null (field already nil)	no (nil == nil)	yes, as nil	no-op write
	identical value	no (value == base)	yes, same value	no-op write
	[] on an embed	no (both empty)	yes, as []	clears the array
	new value	yes	yes, casted value	updates

In the third and fourth rows, cast records no change. This does not affect the result: the base value equals the provided value, so apply_changes returns it and presence includes the key.
Do not use bare apply_changes/1 output for persistence. The full struct does not distinguish omitted from provided fields, which turns a PATCH into a full-record write.
force_changes: and empty_values:
force_changes: exists for designs that extract from the change list, where a value provided identical to the current one records no change and is dropped from the write. Enact's extraction does not read the change list, so this option is not needed.
empty_values: remains available, but it is a host decision. The runner never calls cast/3; the input module's changeset heads do. Ecto's default treats "" and whitespace-only strings as empty on every field type, so "name": "" behaves like an explicit nil-clear — and "count": "" on an integer field silently becomes a null-clear instead of a type error.
Enact.InputSchema.cast_input/4 packages the recommended JSON API policy so this does not have to be configured per cast call. It derives empty-string handling from each field's type: "" on a non-string field is a cast error ("is invalid"); empty-ish :string values ("", whitespace-only) coalesce to nil, while non-empty values pass through as sent — casting interprets input, it never modifies values. One option declares the exception: keep_empty_strings: for fields where "" is a value. Enact.Test.assert_rejects_empty_strings/3 verifies the non-string outcome in CI regardless of which casting mechanism a module uses.
Column convention
The default cast behavior is correct when optional scalar columns are nullable with no default, making NULL the single representation of an empty value:
	Empty input ("", " ") coalesces to nil through the default cast, with no options or normalization helpers.
	Explicit null is a clear, which is what Enact's nil-clear semantics express. No null-rejection rules are needed.
	Omission leaves the column NULL. Storage NULL, ctx.subject values, and JSON null are the same value, so serializers do not translate on reads.

NOT NULL DEFAULT '' columns conflict with this behavior. On such columns "" is a valid value, but the default cast converts it to nil, which then violates the NOT NULL constraint at persistence. If you cannot migrate the column to nullable, declare the exception: list those fields in cast_input/4's keep_empty_strings: option, and add a host test asserting that "" survives casting. The qualifying fields are mechanically derivable — any persistence field whose struct default is "". See the Testing guide for the test template and the Recipes guide for a worked example. Use this pattern only for fields where the empty string is meaningful as distinct from absent.
Where change-gating exists
Two behaviors read the change list, and both skips are correct:
	Enact.Validations.unique/3 skips fields with no change. A value identical to the current one is already persisted and would match the record itself. When the field is changing, pass except: ctx.subject so the current row is not treated as a collision.
	Resolution skips nil reference values, since a clear resolves nothing. Resolution itself is presence-gated: a reference provided with a value identical to the current one still resolves, so a non-nil reference in updates always has a corresponding entry in ctx.assigns.

In your own validations, read values with get_field/2 and detect providedness with Enact.provided?/2. Use provided?/2 for rules that run only when the caller included a key, including []-clears, which a get_change-based check would miss.
Anti-patterns
	Bare apply_changes/1 for persistence. Does not distinguish omitted from provided fields; every PATCH becomes a full-record write and base values are written to the database.
	get_change(cs, :field) || ctx.subject.field. Incorrect under nil-clears: get_change returns nil both when there is no change and when the change is nil, so the fallback restores the old value when the caller cleared the field. Use get_field/2 instead; the base makes it return the correct result-state.
	Seeding embeds in from_subject/1. Engages cast_embed's diff-by-identity behavior and breaks replace-wholesale array semantics.
	default: on input schema fields. With presence-based extraction, a schema default never persists. It causes validations to see a value the write does not contain, and it fills any field from_subject/1 misses in the patch base. Enact.Guardrails raises on it. Declare defaults on the database column instead (see the design spec, section 4.3).



  

    Phoenix Integration

Enact has no Phoenix dependency. A host application wires four integration points itself: the actor, the context calling convention, the controller, and the error renderer. This guide provides reference implementations for each.
Setup
# mix.exs
{:enact, "~> 0.1.0"}

# config/config.exs
config :enact, repo: MyApp.Repo
Contexts
Phoenix contexts remain the application API. Controllers, LiveViews, and jobs call context functions; those functions are one-liners that forward to Enact.run/3, dry_run/3, subject/3, or authorized/3. The action module is the write; the context is the name the rest of the app uses.
# lib/my_app/projects.ex
defmodule MyApp.Projects do
  alias MyApp.Projects.Actions.{ArchiveProject, CreateProject, UpdateProject}

  def create_project(params, opts), do: Enact.run(CreateProject, params, opts)
  def update_project(params, opts), do: Enact.run(UpdateProject, params, opts)
  def archive_project(params, opts), do: Enact.run(ArchiveProject, params, opts)

  def create_project_dry_run(params, opts), do: Enact.dry_run(CreateProject, params, opts)
  def update_project_dry_run(params, opts), do: Enact.dry_run(UpdateProject, params, opts)

  def create_project_authorized(params, opts), do: Enact.authorized(CreateProject, params, opts)
  def update_project_subject(params, opts), do: Enact.subject(UpdateProject, params, opts)

  # reads and load_subject fetchers stay here
end
Keep those bodies as a single Enact.run / Enact.dry_run / Enact.subject / Enact.authorized call. Do not reshape params, stamp persistable fields, or preload records into assigns: — that work belongs in the action (execute/2, load_subject/2, resolvers/0). opts pass through unchanged so :actor, :repo, :assigns, and :confirm_digest work as they do on Enact.run/3.
The one-liners may be generated instead of written by hand:
defmodule MyApp.Projects do
  alias MyApp.Projects.Actions.{ArchiveProject, CreateProject, UpdateProject}

  use Enact.Delegates, actions: [CreateProject, UpdateProject, ArchiveProject]

  # reads and load_subject fetchers stay here
end
Names come from the last segment of each action module (CreateProject → create_project / create_project_dry_run / create_project_subject / create_project_authorized). All four wrappers are generated for every listed action. Handwritten delegates remain valid; the helper is opt-in.
Action tests and IEx may still call Enact.run/3 directly. That is the implementation API, not a second door for controllers.
The actor: your scope struct
In Phoenix 1.8+, the recommended actor is the scope struct. Enact never reads the actor itself; only your authorize/1 callbacks and fetchers do.
Projects.create_project(params, actor: conn.assigns.current_scope)
Implement the Enact.Actor protocol for your scope struct so Enact can identify anonymous scopes:
# lib/my_app/accounts/scope.ex
defimpl Enact.Actor, for: MyApp.Accounts.Scope do
  def anonymous?(%{user: nil}), do: true
  def anonymous?(_scope), do: false
end
actor: nil always raises. This intentionally conflicts with current_scope: nil on public routes: public endpoints must construct an explicit anonymous scope at the boundary. An anonymous scope can carry a session ID and IP for rate limiting:
# a plug on public pipelines
def assign_public_scope(conn, _opts) do
  assign(conn, :current_scope, MyApp.Accounts.Scope.for_visitor(
    session_id: get_session(conn, :session_id),
    ip: conn.remote_ip
  ))
end
Only actions that declare anonymous?: true in config/0 accept an anonymous actor. All other actions return :forbidden before any pipeline work runs. To audit the unauthenticated write surface, search the codebase for anonymous?: true.
Without scopes
The scope pattern is not required. The actor is opaque to Enact, so any term works. In an application that assigns current_user, pass it directly:
Projects.create_project(params, actor: conn.assigns.current_user)
Authenticated actors need no Enact.Actor implementation; the fallback returns false for any term. Your authorize/1 callbacks and fetchers read ctx.actor as a user struct instead of a scope.
The rule for public endpoints is unchanged: never pass nil. The :anonymous atom is a built-in anonymous actor:
Bookings.create_booking(params, actor: :anonymous)
Unlike an anonymous scope, :anonymous carries no session ID or IP. If your anonymous?: true actions need those for rate limiting or auditing, use a scope-shaped actor instead.
Controllers
Phoenix merges path params into params, so the subject ID (read by load_subject/2) and the request body arrive together. Pass params through unchanged. Jobs and tests may pass atom keys — the runner stringifies them, so actions always see the same string-keyed shape:
defmodule MyAppWeb.ProjectController do
  use MyAppWeb, :controller

  action_fallback MyAppWeb.FallbackController

  alias MyApp.Projects

  def new(conn, _params) do
    with :ok <-
           Projects.create_project_authorized(%{}, actor: conn.assigns.current_scope) do
      render(conn, :new)
    end
  end

  def create(conn, params) do
    with {:ok, project} <- Projects.create_project(params, actor: conn.assigns.current_scope) do
      conn |> put_status(:created) |> render(:show, project: project)
    end
  end

  def edit(conn, params) do
    with {:ok, project} <-
           Projects.update_project_subject(params, actor: conn.assigns.current_scope) do
      render(conn, :edit, project: project)
    end
  end

  def update(conn, params) do
    with {:ok, project} <- Projects.update_project(params, actor: conn.assigns.current_scope) do
      render(conn, :show, project: project)
    end
  end
end
Inertia / HTML form posts
JSON controllers can with on the context function because success is a render and every error is a status. Inertia form posts are different: success, :invalid, and :conflict are Phoenix redirect/2 (Inertia intercepts those). :invalid in particular is not a 422 page — assign_errors/2 (from inertia-phoenix) stashes the changeset and the next GET paints the form. That is the Inertia contract, not Enact's.
:forbidden, :not_found, and :internal still belong to action_fallback. Return the error tuple; do not call the fallback module from the helper. action_fallback only runs when the action returns something other than a %Plug.Conn{}.
# lib/my_app_web/enact.ex
defmodule MyAppWeb.Enact do
  import Inertia.Controller
  import Phoenix.Controller

  def enact_redirect(result, conn, opts) do
    case result do
      {:ok, _} ->
        conn
        |> put_flash(:info, Keyword.fetch!(opts, :success_flash))
        |> redirect(to: Keyword.fetch!(opts, :success_path))

      {:error, %Enact.Error{type: :invalid, changeset: changeset}} ->
        conn
        |> assign_errors(changeset)
        |> redirect(to: Keyword.fetch!(opts, :invalid_path))

      {:error, %Enact.Error{type: :conflict}} ->
        conn
        |> put_flash(:error, Keyword.fetch!(opts, :conflict_flash))
        |> redirect(to: Keyword.get(opts, :conflict_path, Keyword.fetch!(opts, :success_path)))

      {:error, %Enact.Error{type: type} = error}
      when type in [:forbidden, :not_found, :internal] ->
        {:error, error}
    end
  end
end
def create(conn, params) do
  params
  |> Projects.create_project(actor: conn.assigns.current_scope)
  |> enact_redirect(conn,
    success_flash: "Project created",
    success_path: ~p"/projects",
    invalid_path: ~p"/projects/new",
    conflict_flash: "Project could not be created"
  )
end
If the success redirect needs the created record (~p"/projects/#{project}"), take it from {:ok, value}. Conflict has no new record, so that path cannot be the conflict default.
Import the helper from use MyAppWeb, :controller if you want it on every controller. Keep the name prefixed (enact_redirect/3) so it does not collide with Phoenix.Controller.redirect/2, and import with only: so later host helpers do not leak into API controllers.
API controllers should not use this helper. They stay on with {:ok, record} <- Projects.create_project(...).
Rendering errors
One fallback clause handles every action. Because the error taxonomy is closed, this code does not change as actions are added:
defmodule MyAppWeb.FallbackController do
  use MyAppWeb, :controller

  def call(conn, {:error, %Enact.Error{} = error}) do
    conn
    |> put_status(status(error.type))
    |> put_view(json: MyAppWeb.ErrorJSON)
    |> render(:enact, error: error)
  end

  defp status(:invalid), do: :unprocessable_entity
  defp status(:forbidden), do: :forbidden
  defp status(:not_found), do: :not_found
  defp status(:conflict), do: :conflict
  defp status(:internal), do: :internal_server_error
end
defmodule MyAppWeb.ErrorJSON do
  # :invalid is the only type that carries caller-visible detail. The
  # changeset describes the caller's own input, so traverse_errors is safe
  # to serialize. Nested and indexed embed errors (including resolver
  # failures) render correctly with no per-action code.
  def enact(%{error: %Enact.Error{type: :invalid, changeset: changeset}}) do
    %{errors: Ecto.Changeset.traverse_errors(changeset, &translate_error/1)}
  end

  # Default: generic copy by type. Do not echo error.reason.
  def enact(%{error: %Enact.Error{type: type}}) do
    %{errors: %{detail: detail(type)}}
  end

  defp detail(:forbidden), do: "Forbidden"
  defp detail(:not_found), do: "Not found"
  defp detail(:conflict), do: "Conflict"
  defp detail(:internal), do: "Internal server error"

  defp translate_error({msg, opts}) do
    # Gettext-backed in a real app. This renderer is the API-versioning seam.
    Regex.replace(~r"%{(\w+)}", msg, fn _, key ->
      opts |> Keyword.get(String.to_existing_atom(key), key) |> to_string()
    end)
  end
end
Renderer policies:
	404/403 collapse. Rendering :forbidden as 404 prevents responses from revealing that a resource exists. Keep the two types distinct internally; collapse only at the renderer. The policy can be format-specific: HTML (and Inertia) often collapse, JSON APIs often keep 403. Put the clause above the catch-all %Enact.Error{} head:
def call(conn, {:error, %Enact.Error{type: :forbidden}}) do
  if get_format(conn) == "html" do
    call(conn, {:error, :not_found})
  else
    call(conn, {:error, :forbidden})
  end
end

	Forbidden copy. Default 403 is generic. To vary the message, add a clause that matches a host-owned reason from authorize/1 and keep the generic :forbidden head as the fallback. Do not put reason in the JSON. Do not do this for :not_found.
def enact(%{error: %Enact.Error{type: :forbidden, reason: :link_disabled}}) do
  %{errors: %{detail: "This scheduling link is disabled"}}
end

	Stable error codes. Resolver failures carry validation: :resolution in the error metadata, so translate_error/1 can emit machine-readable codes that distinguish reference errors from format errors without string matching.


Constraint errors and stale races
A {:error, %Ecto.Changeset{}} returned from execute/2 rolls the transaction back and is promoted to :invalid. This is how declared constraints (unique_constraint, foreign_key_constraint) surface as ordinary 422 field errors when the database catches a race that pre-flight validation could not.
Stale-entry races arrive through the same channel. Repo.update(changeset, stale_error_field: :lock_version) also returns {:error, changeset}, so without intervention an optimistic-lock failure renders as :invalid with a field error on :lock_version. The correct type for that case is :conflict (409): the input was valid, but the record changed. If an action uses optimistic locking, translate that failure in execute/2. The runner passes an %Enact.Error{} through unchanged:
@impl Enact.Action
def execute(changeset, ctx) do
  result =
    ctx.subject
    |> Project.changeset(Enact.updates(changeset, ctx))
    |> Ecto.Changeset.optimistic_lock(:lock_version)
    |> ctx.repo.update(stale_error_field: :lock_version)

  case result do
    {:error, %Ecto.Changeset{errors: errors} = failed} ->
      if errors[:lock_version] do
        {:error, Enact.Error.conflict(:stale)}
      else
        # constraint errors continue to flow to :invalid
        {:error, failed}
      end

    other ->
      other
  end
end
The changeset in a promoted constraint error is the persistence changeset, not the input changeset. Keep constraint-bearing field names aligned with the input schema's names, or re-map them in execute/2, so the rendered field addressing matches your API contract.
Some actions should never reflect the persistence changeset to callers — for example, when the action declares no constraints, or when persistence field names do not match the input's. In that case, an unexpected changeset error indicates that validation and persistence have drifted, which is a bug rather than caller input. Log it and return :internal. The default renderer does not echo reason, so the caller sees a generic 500:
require Logger

@impl Enact.Action
def execute(changeset, ctx) do
  updates = Enact.updates(changeset, ctx)

  case ctx.repo.insert(Project.changeset(%Project{}, updates)) do
    {:ok, project} ->
      {:ok, project}

    {:error, failed} ->
      Logger.error(
        "#{inspect(__MODULE__)} persistence changeset rejected pre-validated input: " <>
          inspect(failed.errors)
      )

      {:error, Enact.Error.internal(:persistence_rejected)}
  end
end
Every :internal occurrence in production logs is a defect to fix. It is never rendered to callers.
Background jobs
Background jobs use the same calling convention. Reconstruct the actor from stored identity; do not bypass the context (or the action behind it):
defmodule MyApp.Workers.ArchiveStaleProject do
  use Oban.Worker

  alias MyApp.Projects

  @impl Oban.Worker
  def perform(%{args: %{"project_id" => id, "actor_user_id" => user_id}}) do
    actor = MyApp.Accounts.scope_for_user_id!(user_id)

    case Projects.archive_project(%{"id" => id}, actor: actor) do
      {:ok, _} -> :ok
      # already archived or deleted: don't retry
      {:error, %Enact.Error{type: :not_found}} -> :ok
      {:error, error} -> {:error, error}
    end
  end
end
Telemetry
The runner emits telemetry events for every action. Attach a handler for metrics and audit trails:
:telemetry.attach_many(
  "enact-audit",
  [
    [:enact, :action, :run],
    [:enact, :action, :run, :error],
    [:enact, :action, :dry_run],
    [:enact, :action, :dry_run, :error],
    [:enact, :action, :subject],
    [:enact, :action, :subject, :error],
    [:enact, :action, :authorized],
    [:enact, :action, :authorized, :error]
  ],
  &MyApp.Audit.handle_enact_event/4,
  nil
)
Error events carry type: in metadata, so a handler can record entries such as "actor X attempted Y, denied :forbidden". Dry runs, subject loads, and authorized checks emit separate events, so previews and form GETs are auditable without inflating execution counts.
Confirmation flows (agent surfaces, MCP tools)
{:ok, preview} = Projects.update_project_dry_run(params, actor: actor)
# present preview.updates for confirmation (diff against preview.subject), then:
{:ok, project} =
  Projects.update_project(params, actor: actor, confirm_digest: preview.digest)
The digest binds the action, mode, locator params, and updates map; any difference between the previewed change and the confirming run returns :conflict. Diff preview.updates against preview.subject. The preview lists resolver names only; if the confirmation UI needs display information (for example, the resolved user's name), render it host-side from your own reads.


  

    Recipes

End-to-end examples of common patterns. The samples follow the documented conventions: context-scoped module layout, private fetchers dispatching to context functions, and presence-preserving handling of Enact.updates/2 output.
1. Embedded data end-to-end
An order with line items: nested input casting, per-item validation, batch resolution of item references, and replace-wholesale persistence. The item schema is defined before the parent, because an alias referenced by embeds_many must resolve when the schema block expands.
# lib/my_app/orders/inputs/line_item_input.ex
defmodule MyApp.Orders.Inputs.LineItemInput do
  use Ecto.Schema
  import Ecto.Changeset
  # item schemas take the bare import — changeset/2 is invoked by
  # cast_embed, so they do not adopt the behaviour via use
  import Enact.InputSchema, only: [cast_input: 3]

  @primary_key false
  embedded_schema do
    field :product_id, :string
    field :quantity, :integer
  end

  def changeset(item, params) do
    item
    |> cast_input(params, [:product_id, :quantity])
    |> validate_required([:product_id, :quantity])
    |> validate_number(:quantity, greater_than: 0)
  end
end
# lib/my_app/orders/inputs/order_input.ex
defmodule MyApp.Orders.Inputs.OrderInput do
  use Ecto.Schema
  use Enact.InputSchema
  import Ecto.Changeset

  @primary_key false
  embedded_schema do
    field :note, :string
    embeds_many :items, MyApp.Orders.Inputs.LineItemInput
  end

  @impl Enact.InputSchema
  def changeset(base, params, :create) do
    base
    |> cast_input(params, [:note])
    |> cast_embed(:items, required: true)
  end

  @impl Enact.InputSchema
  def fields(:create), do: [:note, :items]
end
# lib/my_app/orders/actions/create_order.ex
defmodule MyApp.Orders.Actions.CreateOrder do
  use Enact.Action

  alias MyApp.Catalog
  alias MyApp.Orders.Inputs.OrderInput
  alias MyApp.Orders.Order

  @impl Enact.Action
  def input, do: OrderInput

  @impl Enact.Action
  def authorize(ctx), do: MyApp.Policy.can?(ctx.actor, :create_order)

  @impl Enact.Action
  def resolvers do
    [products: {[:items, :product_id], &fetch_products/2}]
  end

  @impl Enact.Action
  def execute(changeset, ctx) do
    updates = Enact.updates(changeset, ctx)
    products = ctx.assigns.products

    # items arrive as plain maps; swap public IDs for internal foreign keys
    # by reading the batch lookup map
    items =
      Enum.map(updates.items, fn item ->
        %{item | product_id: products[item.product_id].id}
      end)

    %Order{org_id: ctx.actor.org.id}
    |> Order.changeset(%{updates | items: items})
    |> ctx.repo.insert()
  end

  # one query for all unique IDs; scoped by the trust anchor first, and
  # precise messages only for records the scoped query returned
  defp fetch_products(public_ids, ctx) do
    ctx.actor
    |> Catalog.get_products_by_public_ids(public_ids)
    |> Map.new(fn product ->
      value = if product.active?, do: product, else: {:error, "is no longer available"}
      {product.public_id, value}
    end)
  end
end
An unknown or cross-tenant product_id is absent from the fetcher's result map and renders the generic "not found" at the correct item index. A deactivated product in the caller's own tenant renders the precise message. Both arrive as ordinary 422 field errors.
2. Flattening an embed into columns
The API models an address as a nested object; the table stores flat columns. The translation lives in execute/2, and each of the three presence cases (omitted, explicit null, provided) must be handled:
# lib/my_app/customers/actions/update_customer.ex
defmodule MyApp.Customers.Actions.UpdateCustomer do
  use Enact.Action

  alias MyApp.Customers
  alias MyApp.Customers.Customer
  alias MyApp.Customers.Inputs.CustomerInput

  @impl Enact.Action
  def config, do: [mode: :patch]

  @impl Enact.Action
  def input, do: CustomerInput

  @impl Enact.Action
  def load_subject(%{"id" => id}, ctx), do: Customers.get_customer(ctx.actor, id)

  @impl Enact.Action
  def authorize(ctx), do: MyApp.Policy.can?(ctx.actor, :update, ctx.subject)

  @impl Enact.Action
  def execute(changeset, ctx) do
    updates =
      changeset
      |> Enact.updates(ctx)
      |> flatten_address()

    ctx.subject
    |> Customer.changeset(updates)
    |> ctx.repo.update()
  end

  @address_columns ~w(address_line1 address_city address_postal_code)a

  defp flatten_address(updates) do
    case Map.fetch(updates, :address) do
      # omitted → columns untouched
      :error ->
        updates

      # explicit null → clear every column
      {:ok, nil} ->
        updates
        |> Map.delete(:address)
        |> Map.merge(Map.from_keys(@address_columns, nil))

      # provided → the embed arrives as a plain map; spread it
      {:ok, address} ->
        updates
        |> Map.delete(:address)
        |> Map.merge(%{
          address_line1: address.line1,
          address_city: address.city,
          address_postal_code: address.postal_code
        })
    end
  end
end
Use Map.fetch/2, not Map.get/2. Map.get returns nil for both "omitted" and "explicit null", collapsing two cases that must map differently. In the input module, from_subject/1 leaves the address embed unseeded; a validation that needs the current address reads ctx.subject directly.
3. Reading resolver assigns in execute/2
The scalar counterpart of recipe 1's batch lookup. Resolution is presence-gated, so whenever a non-nil reference appears in updates, the resolved record is present in ctx.assigns. Handle the three presence cases explicitly:
@impl Enact.Action
def resolvers do
  [owner: {:owner_id, &fetch_owner/2}]
end

@impl Enact.Action
def execute(changeset, ctx) do
  updates =
    changeset
    |> Enact.updates(ctx)
    |> translate_owner(ctx)

  ctx.subject
  |> Project.changeset(updates)
  |> ctx.repo.update()
end

defp translate_owner(updates, ctx) do
  case Map.fetch(updates, :owner_id) do
    # omitted → untouched
    :error -> updates
    # explicit null → the foreign key clears; nil passes through
    {:ok, nil} -> updates
    # provided → resolved and re-authorized; swap public ID for internal
    {:ok, _public_id} -> %{updates | owner_id: ctx.assigns.owner.id}
  end
end

defp fetch_owner(public_id, ctx) do
  case MyApp.Accounts.get_org_user(ctx.actor, public_id) do
    nil -> :error
    user -> {:ok, user}
  end
end
4. Dry-run previews in an MCP response
A two-phase confirmation flow for an agent-facing tool. preview.updates is plain atom-keyed data, embeds included, so it JSON-encodes directly. Serialize preview.subject for the current side of the diff. The digest, not the serialized display, carries confirmation integrity, so the display format can be reshaped freely.
defmodule MyAppWeb.MCP.UpdateProjectTool do
  alias MyApp.Projects

  # Phase 1: no confirmation token → validate fully, reflect back, change nothing
  def call(params, scope) do
    case Projects.update_project_dry_run(params, actor: scope) do
      {:ok, preview} ->
        current =
          preview.subject
          |> Projects.serialize()
          |> Map.take(Map.keys(preview.updates))

        %{
          status: "needs_confirmation",
          changes: preview.updates,
          current: current,
          # resolver names only — loaded records never reach the agent; if
          # the UI needs display info, render it host-side from your own reads
          resolved: preview.resolved,
          confirm_digest: preview.digest
        }

      {:error, error} ->
        render_error(error)
    end
  end

  # Phase 2: same params + the digest → execute
  def call(params, scope, confirm_digest) do
    case Projects.update_project(params, actor: scope, confirm_digest: confirm_digest) do
      {:ok, project} ->
        %{status: "done", project: Projects.serialize(project)}

      {:error, %Enact.Error{type: :conflict}} ->
        %{status: "stale", message: "The change no longer matches what was confirmed. Preview again."}

      {:error, error} ->
        render_error(error)
    end
  end
end
The full pipeline runs again on confirm — authorization, validation, resolution — so a digest match with changed world state still surfaces :invalid or :not_found normally. The digest binds the action, mode, locator params, and updates map. Both phases emit separate telemetry events, so audit trails count previews and executions separately.
5. Empty-string-at-rest columns
Most optional text should be nullable at rest, with NULL as the single representation of empty; those fields need none of the following (see the column convention in the Change Detection guide). On a NOT NULL DEFAULT '' column, however, "" is a valid value, and default cast behavior converts it to nil, which violates the NOT NULL constraint at persistence. The pattern: declare the exception in cast_input/4's keep_empty_strings: option, and reject explicit null in the action.
# lib/my_app/customers/inputs/customer_input.ex
defmodule MyApp.Customers.Inputs.CustomerInput do
  use Ecto.Schema
  use Enact.InputSchema
  import Ecto.Changeset

  @primary_key false
  embedded_schema do
    field :name, :string
    field :summary, :string
  end

  @scalars ~w(name summary)a
  # summary is not in @required: on create, omission must be allowed so
  # the column default applies, and validate_required would reject it
  @required ~w(name)a

  # NOT NULL DEFAULT '' columns: "" is a value, so empties must survive
  # casting instead of coalescing to nil
  @empty_string_text ~w(summary)a

  @impl Enact.InputSchema
  def changeset(base, params, :create) do
    base
    |> cast_input(params, @scalars, keep_empty_strings: @empty_string_text)
    |> validate_required(@required)
  end

  # the :patch head applies the same cast; from_subject/1 projects the
  # stored value (possibly "") like any other scalar
end
The emptiness test is trimmed, so " " counts as empty, and the keep_empty_strings: disposition stores it as "" rather than coalescing to nil.
Explicit null is the remaining case. The field must never be null but may be blank, which validate_required cannot express: it rejects both nil and blank strings. Only presence distinguishes "omitted" (allowed — the column default applies) from "explicit null" (an error), so the rule lives in the action's validate/2:
@impl Enact.Action
def validate(changeset, ctx) do
  if Enact.provided?(ctx, :summary) and is_nil(get_field(changeset, :summary)) do
    add_error(changeset, :summary, "can't be null")
  else
    changeset
  end
end
The cases resolve as follows: "" persists as ""; " " counts as empty and persists as ""; explicit null returns a 422 on :summary; omitted leaves the field untouched, and create inserts fall to the column default. The drift test in the Testing guide catches any ""-at-rest field wired with a plain cast.
6. Partial updates on a singular embed
The default embed contract is replace-wholesale. For a singular config object — a booking_policy with several flags — that forces callers to send the whole object to change one flag. Declaring the embed in the input module's partial_embeds/1 manifest switches it to partial-object semantics: Enact.updates/2 filters its sub-keys by presence, so the updates map, previews, and confirmation digests carry exactly what the caller sent, one level down. (embeds_many cannot be declared partial — merging arrays requires item identity, which is a different contract; the guardrails enforce this.)
PATCH { "booking_policy": { "allow_booking": false } }
The item schema stays shape-only. Partial sends cast over an empty struct, so validate_required here would wrongly reject them:
# lib/my_app/scheduling/inputs/booking_policy_input.ex
defmodule MyApp.Scheduling.Inputs.BookingPolicyInput do
  use Ecto.Schema
  import Enact.InputSchema, only: [cast_input: 3]

  @primary_key false
  embedded_schema do
    field :allow_booking, :boolean
    field :allow_reschedule, :boolean
  end

  def changeset(item, params) do
    cast_input(item, params, [:allow_booking, :allow_reschedule])
  end
end
# lib/my_app/scheduling/inputs/link_input.ex
defmodule MyApp.Scheduling.Inputs.LinkInput do
  use Ecto.Schema
  use Enact.InputSchema
  import Ecto.Changeset

  @primary_key false
  embedded_schema do
    field :name, :string
    embeds_one :booking_policy, MyApp.Scheduling.Inputs.BookingPolicyInput
  end

  @impl Enact.InputSchema
  def changeset(base, params, _mode) do
    base
    |> cast_input(params, [:name])
    |> cast_embed(:booking_policy)
  end

  @impl Enact.InputSchema
  def fields(_mode), do: [:name, :booking_policy]

  @impl Enact.InputSchema
  def from_subject(link), do: %__MODULE__{name: link.name}

  @impl Enact.InputSchema
  def partial_embeds(_mode), do: [:booking_policy]
end
execute/2 merges the partial object over the current value using Enact.merged/4 — the same function merged-result validations use, so the merge semantics have one definition:
@impl Enact.Action
def execute(changeset, ctx) do
  updates =
    changeset
    |> Enact.updates(ctx)
    |> merge_booking_policy(changeset, ctx)

  ctx.subject
  |> Link.changeset(updates)
  |> ctx.repo.update()
end

defp merge_booking_policy(updates, changeset, ctx) do
  case Map.fetch(updates, :booking_policy) do
    # provided → the result-state view is the merged object
    {:ok, %{}} ->
      %{updates | booking_policy: Enact.merged(changeset, ctx, :booking_policy)}

    # omitted (untouched) or explicit null (clears the whole object)
    _ ->
      updates
  end
end
When the policy is stored as flat columns instead of an embed, the merge disappears: provided sub-keys become columns, and omitted columns stay out of the write — untouched by the same presence semantics that protect top-level fields:
defp flatten_booking_policy(updates, ctx) do
  case Map.fetch(updates, :booking_policy) do
    {:ok, %{} = partial} ->
      updates
      |> Map.delete(:booking_policy)
      # atoms derive from the input schema's closed field set
      |> Map.merge(Map.new(partial, fn {key, value} -> {:"policy_#{key}", value} end))

    {:ok, nil} ->
      updates
      |> Map.delete(:booking_policy)
      |> Map.merge(%{policy_allow_booking: nil, policy_allow_reschedule: nil})

    :error ->
      updates
  end
end
The cases resolve as follows: a provided sub-key merges; an explicitly-null sub-key is present as nil and clears that flag; an omitted sub-key is absent and stays untouched; a null for the whole object clears everything. Previews and digests contain exactly the provided sub-keys, so the user confirms the partial change itself.
Validating the merged result
Validations see the partially-cast object, not the merged result — the base never seeds embeds, so get_field on the item changeset returns nil for omitted sub-keys. Per-key intrinsic rules (formats, bounds) still work in the item schema, since Ecto validators skip absent and nil changes. But a rule about the merged policy belongs in the action's validate/2, against the result-state view built by Enact.merged/4 — the same function the execute merge uses:
@impl Enact.Action
def validate(changeset, ctx) do
  policy = Enact.merged(changeset, ctx, :booking_policy)

  if policy.allow_booking or policy.allow_reschedule do
    changeset
  else
    add_error(changeset, :booking_policy, "must keep at least one option enabled")
  end
end
merged/4 reads each sub-key from the caller's casted value where provided — including explicit nulls, which correctly read as clears — and from ctx.subject where not. The key list derives from the schema by default. See its documentation for the full case table (whole-object nulls, missing current objects).
Displaying partial changes in a confirmation flow
A confirmation preview serves two purposes. The digest binds the delta: the exact change the user confirms. The display provides context: the current and resulting values. Bind the delta; display both. Extending recipe 4's response shape:
current = Scheduling.serialize(preview.subject).booking_policy
resulting = Map.merge(current, preview.updates.booking_policy)

%{
  changes: preview.updates,                  # the delta; bound by the digest
  current: %{booking_policy: current},
  resulting: %{booking_policy: resulting},   # display context; not digest-bound
  confirm_digest: preview.digest
}
resulting is computed against current state, which can change before the confirming run. The design makes no reservation: the confirming run re-validates against current state, and the confirmed delta is what executes.


  

    Testing Host Applications

Enact's own suite covers the pipeline mechanics. Write these tests in the host application; they depend on your actions, schemas, and tenancy model. Import only the helpers you need — import Enact.Test, only: [assert_invalid: 2, assert_rejects_empty_strings: 2, build_ctx: 1]. Phoenix DataCase already defines errors_on/1; use that, or call Enact.Test.errors_on/1 if the host has no helper. A blanket import Enact.Test will collide on errors_on/1.
The action registry
The templates enumerate your actions, so maintain one explicit list, plus a completeness check so new actions cannot be omitted from the suite:
defmodule MyApp.Actions do
  @actions [
    MyApp.Projects.Actions.CreateProject,
    MyApp.Projects.Actions.UpdateProject,
    MyApp.Projects.Actions.ArchiveProject
    # every action, no exceptions
  ]

  def all, do: @actions
end
test "the registry lists every action module" do
  {:ok, modules} = :application.get_key(:my_app, :modules)

  implemented =
    for mod <- modules,
        match?({:module, _}, Code.ensure_loaded(mod)),
        Enact.Action in List.flatten(
          Keyword.get_values(mod.module_info(:attributes), :behaviour)
        ),
        do: mod

  assert Enum.sort(implemented) == Enum.sort(MyApp.Actions.all())
end
1. Guardrails in CI
The runner checks input schemas lazily on first run. This test moves the check to CI:
test "every input schema passes guardrails" do
  for action <- MyApp.Actions.all(), input = action.input(), input != nil do
    mode = Keyword.get(action.config(), :mode, :create)
    Enact.Guardrails.assert_valid_input_schema!(input, mode: mode)
  end
end
2. Cross-tenant sweep
Run every action as a tenant-A actor against tenant-B's subject and references. Subjects must return :not_found. Foreign references must produce only the generic "not found" field error; a precise message would reveal that the record exists.
describe "cross-tenant isolation" do
  setup do
    %{actor: scope_fixture(org: org_fixture()), other_org: org_fixture()}
  end

  test "tenant-B subjects are not found", %{actor: actor, other_org: other_org} do
    foreign_project = project_fixture(org: other_org)

    params = %{"id" => foreign_project.public_id, "name" => "hijack"}
    assert {:error, %Enact.Error{type: :not_found}} =
             Enact.run(MyApp.Projects.Actions.UpdateProject, params, actor: actor)
  end

  test "tenant-B references produce only the generic message", %{actor: actor, other_org: other_org} do
    foreign_user = user_fixture(org: other_org)

    # enumerate reference fields from the resolvers/0 manifests
    for action <- MyApp.Actions.all(), {_name, {spec, _fetcher}} <- action.resolvers() do
      params = valid_params_for(action, actor) |> put_reference(spec, foreign_user.public_id)
      changeset = assert_invalid(Enact.run(action, params, actor: actor))

      for {_field, messages} <- errors_on(changeset), message <- List.wrap(messages) do
        assert message == "not found",
               "#{inspect(action)} leaked a precise message for a foreign reference: #{message}"
      end
    end
  end
end
valid_params_for/2 and put_reference/3 are application-specific: a per-action map of known-good params, with the reference field swapped. The scalar spec form is a field atom; the batch form is [embed_field, item_field].
Anonymous-capable actions (anonymous?: true) scope fetchers through the subject's tenant, not the actor. Run each as an anonymous actor against a reference in another tenant:
test "anonymous actions do not resolve references outside the subject's tenant" do
  for action <- MyApp.Actions.all(),
      Keyword.get(action.config(), :anonymous?, false),
      {_name, {spec, _fetcher}} <- action.resolvers() do
    subject = public_subject_for(action, org_fixture())
    foreign = user_fixture(org: org_fixture())

    params =
      valid_anonymous_params_for(action, subject)
      |> put_reference(spec, foreign.public_id)

    changeset = assert_invalid(Enact.run(action, params, actor: :anonymous))

    for {_field, messages} <- errors_on(changeset), message <- List.wrap(messages) do
      assert message == "not found",
             "#{inspect(action)} leaked a precise message for a foreign reference: #{message}"
    end
  end
end
public_subject_for/2 and valid_anonymous_params_for/2 are application-specific: a visible-by-slug subject in one tenant, and params that load it.
3. The PATCH matrix (per patch action)
Eight cases per patch action. This example uses an UpdateProject action where name is required, priority is optional, and milestones is an embed:
describe "UpdateProject PATCH semantics" do
  setup do
    project = project_fixture(name: "Old", priority: 3, milestones: [milestone_fixture()])
    %{actor: scope_for(project), project: project}
  end

  test "omitted keys are untouched", %{actor: actor, project: project} do
    {:ok, updated} = Enact.run(UpdateProject, %{"id" => project.public_id, "priority" => 9}, actor: actor)
    assert updated.name == "Old"
    assert updated.priority == 9
  end

  test "explicit null clears an optional scalar", ctx do
    {:ok, updated} = run_patch(ctx, %{"priority" => nil})
    assert updated.priority == nil
  end

  test "explicit null on a required field is :invalid", ctx do
    assert_invalid(run_patch_raw(ctx, %{"name" => nil}), on: :name)
  end

  test "an omitted required-but-populated field passes validate_required", ctx do
    assert {:ok, _} = run_patch_raw(ctx, %{"priority" => 9})
  end

  test "[] clears the array (and presence-gated validations still run)", ctx do
    {:ok, updated} = run_patch(ctx, %{"milestones" => []})
    assert updated.milestones == []
  end

  test "provided-identical persists as a no-op write", ctx do
    assert {:ok, updated} = run_patch(ctx, %{"name" => "Old"})
    assert updated.name == "Old"
  end

  test "a provided reference re-resolves; an absent one survives", ctx do
    # provided (even identical) → the fetcher runs, re-authorizing the reference
    # absent → untouched, no fetcher call
  end
end
4. The create matrix
test "omitted optionals fall to DB defaults" do
  {:ok, project} = Enact.run(CreateProject, %{"name" => "A", "slug" => "a"}, actor: actor)
  # the column default applies
  assert project.priority == 1
end

test "explicit nil on a required field fails validate_required" do
  assert_invalid(
    Enact.run(CreateProject, %{"name" => nil, "slug" => "a"}, actor: actor),
    on: :name
  )
end
5. Projection completeness (per patch-mode input module)
If from_subject/1 omits a field, validations can no longer distinguish nil-clears from omissions for that field. This test fails in CI instead:
test "ProjectInput.from_subject/1 is total over scalar fields" do
  # every field populated with a non-nil value
  project = fully_populated_project_fixture()
  base = ProjectInput.from_subject(project)

  embeds = ProjectInput.__schema__(:embeds)

  for field <- ProjectInput.fields(:patch), field not in embeds do
    refute is_nil(Map.get(base, field)),
           "from_subject/1 projects no value for #{inspect(field)}"
  end

  # embeds stay at structural defaults — never seeded
  for embed <- embeds do
    assert Map.get(base, embed) in [[], nil]
  end
end
6. Resolver coverage
This test catches reference fields added without a resolver. Without one, the raw public-ID string reaches persistence:
# legitimately opaque _id fields (external references, idempotency keys) —
# exceptions stay visible instead of weakening the rule
@allowlist %{
  MyApp.Payments.Actions.RecordExternalCharge => [:provider_charge_id]
}

test "every *_id input field has a resolver" do
  for action <- MyApp.Actions.all(), input = action.input(), input != nil do
    mode = Keyword.get(action.config(), :mode, :create)
    allowed = Map.get(@allowlist, action, [])

    covered =
      Enum.flat_map(action.resolvers(), fn
        {_name, {field, _fetcher}} when is_atom(field) -> [field]
        {_name, {[_embed, item_field], _fetcher}} -> [item_field]
      end)

    for field <- input.fields(mode),
        String.ends_with?(Atom.to_string(field), "_id"),
        field not in allowed do
      assert field in covered,
             "#{inspect(action)}: #{inspect(field)} has no resolver and is not allowlisted"
    end
  end
end
7. Doc-schema reconciliation (if you document your API)
Enact has no knowledge of OpenApiSpex. Drift prevention is a host-side comparison of the fields/1 manifests against your documentation source of truth:
test "ProjectInput matches the documented request schema" do
  documented = MyAppWeb.Schemas.ProjectCreateRequest.schema().properties |> Map.keys() |> Enum.sort()
  actual = ProjectInput.fields(:create) |> Enum.sort()

  assert documented == actual,
         "API docs and input schema have drifted — change both deliberately"
end
8. Empty-string-at-rest drift
Any persistence field whose struct default is "" is an empty-string-at-rest column (NOT NULL DEFAULT ''). Its input cast must preserve "" instead of coalescing it to nil (see recipe 5 in the Recipes guide). This test derives those fields mechanically and fails when one is wired with a plain cast:
# {input module, persistence schema, mode} for every input casting such fields
@empty_string_pairs [
  {CustomerInput, Customer, :create},
  {CustomerInput, Customer, :patch}
]

defp empty_string_fields(schema) do
  for field <- schema.__schema__(:fields),
      Map.get(struct(schema), field) == "",
      do: field
end

test "empty-string-at-rest fields survive input casting" do
  for {input, persistence, mode} <- @empty_string_pairs,
      field <- empty_string_fields(persistence),
      field in input.fields(mode) do
    changeset = input.changeset(struct(input), %{Atom.to_string(field) => ""}, mode)

    assert Ecto.Changeset.get_field(changeset, field) == "",
           "#{inspect(input)} coalesced \"\" to nil for #{inspect(field)} — " <>
             "list it in cast_input/4's keep_empty_strings: option"
  end
end
9. Empty-string strictness
Ecto's default cast silently coerces "" to nil on every field type. On non-string fields that turns malformed input into a null-clear instruction instead of a cast error. Enact.Test.assert_rejects_empty_strings/3 probes each non-string castable field with "" and fails unless the module reports a cast error:
test "non-string fields reject empty strings" do
  for action <- MyApp.Actions.all(), input = action.input(), input != nil do
    mode = Keyword.get(action.config(), :mode, :create)
    assert_rejects_empty_strings(input, mode)
  end
end
The probe checks behavior, not mechanism: it passes for modules using Enact.InputSchema.cast_input/4 and for modules using stock cast with empty_values: []. Pass except: for fields whose custom types accept "" deliberately.

A thin, behaviour-based action layer for application write operations.
Enact standardizes the shape of every write:
load → authorize → cast → validate → resolve → execute → after_commit
Actions implement Enact.Action; input casting and validation are plain
Ecto via Enact.InputSchema modules; results are {:ok, result} or
{:error, %Enact.Error{}} with a closed, HTTP-shaped error taxonomy.
Enact.run(CreateProject, params, actor: conn.assigns.current_scope)
Options
	:actor — required; opaque to Enact (only the action's authorize/1
and fetchers read it). actor: nil always raises ArgumentError —
anonymous callers pass an explicit anonymous actor instead (see
Enact.Actor), permitted only by actions declaring anonymous?: true.
	:repo — the Ecto repo; defaults to config :enact, repo: MyApp.Repo.
	:assigns — optional map merged into ctx.assigns, the documented
channel for request metadata (IP, session id) that isn't part of the
actor. Resolver-stashed keys are merged after and win on collision.
Never pass pre-loaded domain records or persistable fields here —
fetching belongs in load_subject/2 / resolvers/0; persistable
values are params or stamped in execute/2.

Unknown options raise ArgumentError — a misspelled option (an
assigns: typo, or worse, a confirm_digest: typo silently skipping
the confirmation check) must never be ignored.
Error normalization
	load_subject/2 returning nil → :not_found
	authorize/1 returning false → :forbidden; {:error, reason} →
:forbidden with that reason ({:error, :foo} becomes
{:error, %Enact.Error{type: :forbidden, reason: :foo}})
	post-validate invalid changeset → :invalid (one response carries
all cast + validation errors; there is no cast-stage fast-fail)
	%Ecto.Changeset{} error from execute (declared constraints) →
promoted to :invalid
	any other execute failure → :internal

Telemetry
The runner emits (measurements %{duration: native_time}; metadata
%{action:, mode:, actor:}; error events additionally carry type:,
the Enact.Error type):
	[:enact, :action, :run] / [:enact, :action, :run, :error]
	[:enact, :action, :dry_run] / [:enact, :action, :dry_run, :error]
	[:enact, :action, :subject] / [:enact, :action, :subject, :error]
	[:enact, :action, :authorized] / [:enact, :action, :authorized, :error]
— distinct events so form GETs, previews, and executions are
never conflated

The run event fires after a successful commit but before
after_commit/2 runs, so a raising side effect cannot suppress the
audit record of a committed write.

      


      
        Summary


  
    Functions
  


    
      
        authorized(action, params, opts)

      


        Authorizes the actor to perform the action. No body, no write.



    


    
      
        dry_run(action, params, opts)

      


        Runs the side-effect-free front of the pipeline — load, authorize, cast,
validate, resolve — then stops before any write, returning
{:ok, %Enact.Preview{}} or the identical error surface to run/3.



    


    
      
        merged(changeset, ctx, embed, keys \\ nil)

      


        Builds the per-sub-key result-state view of a partial embed
(partial_embeds/1, see Enact.InputSchema) — the values the object
will hold after the write.



    


    
      
        provided?(context, key)

      


        Whether the caller provided a key (or path) in the raw params — the
reification of "what did the caller say?".



    


    
      
        run(action, params, opts)

      


        Runs an action through the full pipeline.



    


    
      
        subject(action, params, opts)

      


        Loads the action's subject and authorizes the actor. No body, no write.



    


    
      
        updates(changeset, ctx)

      


        Extracts the updates map from a post-validation changeset: exactly the
castable fields the caller provided, with their casted values.



    





      


      
        Functions


        


  
    
      
    
    
      authorized(action, params, opts)



        
          
        

    

  


  

      

          @spec authorized(module(), map(), keyword()) :: :ok | {:error, Enact.Error.t()}


      


Authorizes the actor to perform the action. No body, no write.
Returns :ok or {:error, %Enact.Error{}} (:forbidden, or
:not_found when load fails). Does not return a record. For a new
form. For edit, archive, or create-under-parent, use subject/3.
Still runs load_subject/2 so authorize/1 sees ctx.subject.
Params keys are stringified exactly as in run/3.

  



  
    
      
    
    
      dry_run(action, params, opts)



        
          
        

    

  


  

      

          @spec dry_run(module(), map(), keyword()) ::
  {:ok, Enact.Preview.t()} | {:error, Enact.Error.t()}


      


Runs the side-effect-free front of the pipeline — load, authorize, cast,
validate, resolve — then stops before any write, returning
{:ok, %Enact.Preview{}} or the identical error surface to run/3.
Built for confirmation flows (agent-facing surfaces, MCP tools): the
preview reflects the casted, normalized updates back for confirmation,
carries the loaded subject for old → new diffs, and its digest feeds
run/3's :confirm_digest option. Authorization runs (don't preview
what you can't do), and distinct telemetry events are emitted so audit
trails never conflate previews with executions.
Params keys are stringified exactly as in run/3.

  



    

  
    
      
    
    
      merged(changeset, ctx, embed, keys \\ nil)



        
          
        

    

  


  

      

          @spec merged(Ecto.Changeset.t(), Enact.Context.t(), atom(), [atom()] | nil) :: map()


      


Builds the per-sub-key result-state view of a partial embed
(partial_embeds/1, see Enact.InputSchema) — the values the object
will hold after the write.
Each key reads the caller's casted value where the key was provided
(an explicit null reads as a clear) and the subject's current value
where it was not. It is used in two places:
	validate/2 — rules about the merged result read it directly:
policy = Enact.merged(changeset, ctx, :booking_policy)

if policy.allow_booking or policy.allow_reschedule,
  do: changeset,
  else: add_error(changeset, :booking_policy, "must keep one option enabled")

	execute/2 — it computes the merged object to persist, using
the same definition validation saw:
%{updates | booking_policy: Enact.merged(changeset, ctx, :booking_policy)}


Do not build this view with get_change(...) || ctx.subject.field:
get_change returns nil both when there is no change and when the
change is nil, so the fallback returns the old value when the caller
sends an explicit null. Presence-gating handles nil-clears correctly.
The key list defaults to the embed's scalar fields, derived from the
schema; pass an explicit list to restrict it. Cases:
	sub-key provided → the casted incoming value (explicit null → nil)
	sub-key omitted → the subject's current value
	whole embed omitted → every key reads the current value
	whole embed explicitly null → every key reads nil (the object is
being cleared)
	no current object (create mode, or a nil subject value) → unprovided
keys read nil

Returns a plain atom-keyed map. On an already-invalid changeset the
incoming values may be incomplete (there is no cast-stage fast-fail);
gate such rules with Enact.Validations.check/2 where that matters.

  



  
    
      
    
    
      provided?(context, key)



        
          
        

    

  


  

      

          @spec provided?(Enact.Context.t(), atom() | [atom() | non_neg_integer()]) :: boolean()


      


Whether the caller provided a key (or path) in the raw params — the
reification of "what did the caller say?".
A key is provided even when its value is nil (an explicit null-clear
is a statement). Accepts a single atom for top-level presence, or a path
where atoms descend into maps (string- or atom-keyed) and non-negative
integers index into lists. Anything unreachable — missing key,
out-of-range index, non-map element — returns false. Never raises and
never converts strings to atoms.
iex> ctx = %Enact.Context{params: %{"note" => nil, "items" => [%{"qty" => 1}]}}
iex> Enact.provided?(ctx, :note)
true
iex> Enact.provided?(ctx, :missing)
false
iex> Enact.provided?(ctx, [:items, 0, :qty])
true
iex> Enact.provided?(ctx, [:items, 5, :qty])
false
iex> Enact.provided?(ctx, [:note, :deep])
false

  



  
    
      
    
    
      run(action, params, opts)



        
          
        

    

  


  

      

          @spec run(module(), map(), keyword()) :: {:ok, term()} | {:error, Enact.Error.t()}


      


Runs an action through the full pipeline.
Returns {:ok, result} (whatever execute/2 produced) or
{:error, %Enact.Error{}}.
Accepts one option beyond the shared set: :confirm_digest — a digest
from a prior dry_run/3 preview. The runner recomputes the digest
post-validation and returns :conflict on mismatch, making "the user
confirmed this exact change to this record" a mechanical guarantee
across the confirmation gap. Non-confirmation callers never pass it.
Params may be atom- or string-keyed at the call site. The runner
stringifies keys (recursively, through plain maps and lists) before
any callback runs, so load_subject/2 and ctx.params always see
the Plug/JSON shape. Values are not rewritten. Both :id and "id"
at the same level raises.

  



  
    
      
    
    
      subject(action, params, opts)



        
          
        

    

  


  

      

          @spec subject(module(), map(), keyword()) ::
  {:ok, struct()} | {:error, Enact.Error.t()}


      


Loads the action's subject and authorizes the actor. No body, no write.
Returns {:ok, subject} or {:error, %Enact.Error{}} (:not_found,
:forbidden). Does not cast, validate, or resolve. Pass locator params
(the path id), not the form body.
The action must load a subject. If load_subject/2 returns
:no_subject, this raises ArgumentError — use authorized/3 for a
new form.
Params keys are stringified exactly as in run/3.

  



  
    
      
    
    
      updates(changeset, ctx)



        
          
        

    

  


  

      

          @spec updates(Ecto.Changeset.t(), Enact.Context.t()) :: map()


      


Extracts the updates map from a post-validation changeset: exactly the
castable fields the caller provided, with their casted values.
Key selection is presence-in-raw-params intersected with the mode's
castable fields (fields/1) — uniform for scalars and embeds. Omitted
keys are absent (untouched on PATCH); explicit null is present as
nil (clears); [] on an embed is present as [] (clears the array).
Embed values are dumped to plain, atom-keyed maps (recursively,
schema-driven; scalar structs like Date and Decimal stay intact),
so the map feeds persistence changesets and JSON encoders directly.
The result is uniformly atom-keyed at every level, and the atoms come
from the schema definitions — never from client params (string keys in
params are matched by presence, not converted), so the atom space stays
closed regardless of input. Ecto.Changeset.cast accepts the map
as-is; just don't merge string-keyed entries into it.
For embeds declared in the input module's partial_embeds/1 manifest,
the dumped map contains only the sub-keys the caller provided (an
explicitly-null sub-key is present as nil; an omitted one is absent).
See Enact.InputSchema.
Never use bare apply_changes/1 output for persistence — it erases
omitted-vs-provided. For input: nil actions this returns %{}.

  


        

      


  

    
Enact.Action behaviour
    



      
The behaviour every action module implements.
use Enact.Action sets @behaviour Enact.Action and overridable
defaults for the optional callbacks — that is its entire body; there is
no DSL and no code generation.
Required: input/0, authorize/1, execute/2. An open write is a
written authorize/1 returning true, never an omitted callback.
Every callback is either pure data (config/0, input/0, resolvers/0)
or a single-purpose function over (changeset | params, ctx). The runner
(Enact.run/3) orchestrates them as:
load → authorize → cast → validate → resolve → execute → after_commit

      


      
        Summary


  
    Callbacks
  


    
      
        after_commit(result, ctx)

      


        Post-commit side effects (job insertion, analytics). Runs strictly after
a successful commit, outside the transaction; its return value is
ignored and it never rolls back. A raise propagates to the caller, but
the write is already committed and the success telemetry event has
already been emitted — the audit trail records the write either way.



    


    
      
        authorize(ctx)

      


        Authorizes the actor against the loaded context. Required — a forgotten
policy is indistinguishable from an open write. Runs before cast —
unauthorized callers trigger no input work.



    


    
      
        config()

      


        Static action configuration.



    


    
      
        execute(changeset, ctx)

      


        Persists the write. Runs inside repo.transaction/1; {:error, reason}
rolls back. A returned %Ecto.Changeset{} error (declared constraints)
is promoted to :invalid; any other error becomes :internal.



    


    
      
        input()

      


        The input-schema module (Enact.InputSchema), or nil for input-less
actions (archive, cancel, resend) — the runner then skips cast and
validate, and Enact.updates/2 returns %{}.



    


    
      
        load_subject(params, ctx)

      


        Fetches the subject — the URL-anchored record the action operates on or
within (the updated record in patch mode; the parent in
create-under-parent). Always invoked. The default is a no-op that
returns :no_subject (leave ctx.subject nil). Returning nil
produces :not_found. Must scope by the trust anchor (§9 of the
design spec). Params are string-keyed — the runner stringifies atom
keys at the run/dry_run/subject/authorized boundary — and values are uncast. Match
%{"id" => id}, not params[:id].



    


    
      
        resolvers()

      


        Declarative reference-resolution spec: [name: {field_or_path, fetcher}].
See Enact.Resolve.



    


    
      
        validate(changeset, ctx)

      


        Ordinary changeset pipeline for operation-specific rules (payload-
intrinsic rules belong in the input module's own validations). Not
invoked for input: nil actions.



    





      


      
        Callbacks


        


  
    
      
    
    
      after_commit(result, ctx)


        (optional)


        
          
        

    

  


  

      

          @callback after_commit(result :: term(), ctx :: Enact.Context.t()) :: term()


      


Post-commit side effects (job insertion, analytics). Runs strictly after
a successful commit, outside the transaction; its return value is
ignored and it never rolls back. A raise propagates to the caller, but
the write is already committed and the success telemetry event has
already been emitted — the audit trail records the write either way.

  



  
    
      
    
    
      authorize(ctx)



        
          
        

    

  


  

      

          @callback authorize(ctx :: Enact.Context.t()) :: boolean() | {:error, term()}


      


Authorizes the actor against the loaded context. Required — a forgotten
policy is indistinguishable from an open write. Runs before cast —
unauthorized callers trigger no input work.
Return values:
	true — proceed
	false — {:error, %Enact.Error{type: :forbidden}}
	{:error, reason} — {:error, %Enact.Error{type: :forbidden, reason: reason}}
({:error, :foo} → {:error, %Enact.Error{type: :forbidden, reason: :foo}})
	{:error, %Enact.Error{}} — passed through

reason is for logs, telemetry, and the host renderer. Do not echo it
wholesale. Match host-owned atoms in the renderer when the 403 copy
should vary; leave the default opaque.
An open write (any non-anonymous actor; or anyone, on anonymous?: true
actions) is a written true, never an omitted callback.

  



  
    
      
    
    
      config()


        (optional)


        
          
        

    

  


  

      

          @callback config() :: keyword()


      


Static action configuration.
Recognized keys (all optional): mode: :create | :patch (default
:create), anonymous?: boolean (default false).

  



  
    
      
    
    
      execute(changeset, ctx)



        
          
        

    

  


  

      

          @callback execute(changeset :: Ecto.Changeset.t(), ctx :: Enact.Context.t()) ::
  {:ok, term()} | {:error, term()}


      


Persists the write. Runs inside repo.transaction/1; {:error, reason}
rolls back. A returned %Ecto.Changeset{} error (declared constraints)
is promoted to :invalid; any other error becomes :internal.

  



  
    
      
    
    
      input()



        
          
        

    

  


  

      

          @callback input() :: module() | nil


      


The input-schema module (Enact.InputSchema), or nil for input-less
actions (archive, cancel, resend) — the runner then skips cast and
validate, and Enact.updates/2 returns %{}.

  



  
    
      
    
    
      load_subject(params, ctx)


        (optional)


        
          
        

    

  


  

      

          @callback load_subject(params :: map(), ctx :: Enact.Context.t()) ::
  struct() | nil | :no_subject | {:error, term()}


      


Fetches the subject — the URL-anchored record the action operates on or
within (the updated record in patch mode; the parent in
create-under-parent). Always invoked. The default is a no-op that
returns :no_subject (leave ctx.subject nil). Returning nil
produces :not_found. Must scope by the trust anchor (§9 of the
design spec). Params are string-keyed — the runner stringifies atom
keys at the run/dry_run/subject/authorized boundary — and values are uncast. Match
%{"id" => id}, not params[:id].

  



  
    
      
    
    
      resolvers()


        (optional)


        
          
        

    

  


  

      

          @callback resolvers() :: keyword()


      


Declarative reference-resolution spec: [name: {field_or_path, fetcher}].
See Enact.Resolve.

  



  
    
      
    
    
      validate(changeset, ctx)


        (optional)


        
          
        

    

  


  

      

          @callback validate(changeset :: Ecto.Changeset.t(), ctx :: Enact.Context.t()) ::
  Ecto.Changeset.t()


      


Ordinary changeset pipeline for operation-specific rules (payload-
intrinsic rules belong in the input module's own validations). Not
invoked for input: nil actions.

  


        

      


  

    
Enact.Actor protocol
    



      
Answers anonymous?/1 for any actor term.
Anonymity must be a pattern-matchable value, never an absence —
actor: nil always raises in the runner. The fallback impl returns
false for any term, so authenticated actors need no impl at all.
Two ways to represent an anonymous caller:
	the bare :anonymous atom — zero-ceremony option for simple apps
	a host-app impl for a scope struct (%Scope{user: nil} → true),
enabling rich anonymous scopes carrying session id / IP for rate
limiting — the idiomatic Phoenix 1.8 shape

An anonymous actor is only permitted by actions declaring
anonymous?: true in config/0; the runner rejects it with
:forbidden everywhere else, before any pipeline work.

      


      
        Summary


  
    Types
  


    
      
        t()

      


        All the types that implement this protocol.



    





  
    Functions
  


    
      
        anonymous?(actor)

      


    





      


      
        Types


        


  
    
      
    
    
      t()



        
          
        

    

  


  

      

          @type t() :: term()


      


All the types that implement this protocol.

  


        

      

      
        Functions


        


  
    
      
    
    
      anonymous?(actor)



        
          
        

    

  


  

      

          @spec anonymous?(t()) :: boolean()


      



  


        

      


  

    
Enact.InputSchema behaviour
    



      
The contract for top-level input-schema modules — plain Ecto embedded
schemas that adopt this behaviour via use Enact.InputSchema, which
sets @behaviour and imports cast_input/4 and nothing more.
use Ecto.Schema, import Ecto.Changeset, and @primary_key false
stay explicit in the module. Plain @behaviour + import remains
equivalent.
The callbacks
	changeset/3 — (base, params, mode); the runner passes the
action's config[:mode] verbatim. Write one head per mode; per-mode
deltas are data (cast lists / required lists), not conditionals.
	fields/1 — the mode-specific castable field list. This is the
introspection surface (__schema__(:fields) cannot distinguish
create-castable from patch-castable); Enact.updates/2 key selection
and host-app reconciliation tests read it.
	from_subject/1 — required iff a patch-mode action uses the module;
create-only modules may omit it.

The validation base
The base argument exists only so validations see result-state;
extraction (Enact.updates/2) ignores the changeset's diff entirely and
keys off presence in raw params. (The system-level walkthrough of how
base, cast, presence, and extraction interact lives in the
Change Detection guide.)
In create mode the base is the empty struct. In patch mode it is
from_subject(ctx.subject) — an explicit, total projection of the loaded
subject into the input representation (public-ID rendering, renames,
representation conversions live here and nowhere else). With the base in
place, validate_required and get_field/2-based cross-field rules work
unmodified on PATCH: an omitted-but-populated required field passes, an
explicit nil-clear fails, and get_field returns the value the record
will have.
from_subject/1 must guarantee:
	totality over scalar fields — every scalar field gets a non-nil
value when the subject has one; a forgotten field silently revives
the nil-clear-vs-omitted ambiguity for that field (host apps test
this via projection-completeness, and blind struct-copying like
Map.take(subject, fields) is forbidden as an implementation)
	embeds are never seeded — they stay at structural defaults
([]/nil); array semantics are replace-wholesale, and seeding
would engage cast_embed's diff-by-identity machinery

Why no field defaults
Omitted fields are excluded from extraction by presence, so a schema
default never persists — it would only mislead validations into seeing a
value the write will not contain. Defaults live in the DB column (or
persistence schema); Enact.Guardrails enforces this.
Nested item schemas
Deliberate asymmetry: nested item modules (invoked by cast_embed, not
the runner) are mode-blind and implement Ecto's native changeset/2 —
they do not adopt this behaviour. They take the bare
import Enact.InputSchema and still cast with cast_input/4, since
item fields have the same empty-string concerns as top-level fields. If
an item schema is later promoted to a top-level input for some action,
it gains a changeset/3 alongside its changeset/2 — same module,
both contracts, no conflict.
Casting
cast_input/4, defined on this module and imported by input modules, is
the casting entry for scalar fields: Ecto.Changeset.cast/4 with JSON
API empty-string semantics derived from field types. See its
documentation for the exact behavior table.
Partial embeds
The default embed contract is replace-wholesale. The optional
partial_embeds/1 manifest declares embeds_one fields that accept
partial objects instead: Enact.updates/2 filters their sub-keys by
presence in raw params, so the updates map (and therefore previews and
confirmation digests) contains exactly the sub-keys the caller sent. An
explicitly-null sub-key is present as nil (a clear); an omitted
sub-key is absent (untouched), matching the omitted-vs-null handling of
top-level fields. execute/2 merges the partial object over the
subject's current value via Enact.merged/4.
embeds_many fields cannot be declared partial — merging arrays
requires item identity, which is a different contract. Validations still
see the partially-cast object (the base never seeds embeds); rules about
the merged result use Enact.merged/4 in the action's validate/2,
and the execute-side merge uses the same function.

    Callbacks
  


    
      
        changeset(base, params, mode)

      


    


    
      
        fields(mode)

      


    


    
      
        from_subject(subject)

      


    


    
      
        partial_embeds(mode)

      


    





  
    Functions
  


    
      
        __using__(opts)

      


        Adopts the contract: sets @behaviour Enact.InputSchema and imports
cast_input/4, nothing more.



    


    
      
        cast_input(base_or_changeset, params, fields, opts \\ [])

      


        Casts scalar params with JSON API semantics.



    





      


      
        Callbacks


        


  
    
      
    
    
      changeset(base, params, mode)



        
          
        

    

  


  

      

          @callback changeset(base :: struct(), params :: map(), mode :: atom()) ::
  Ecto.Changeset.t()


      



  



  
    
      
    
    
      fields(mode)



        
          
        

    

  


  

      

          @callback fields(mode :: atom()) :: [atom()]


      



  



  
    
      
    
    
      from_subject(subject)


        (optional)


        
          
        

    

  


  

      

          @callback from_subject(subject :: struct()) :: struct()


      



  



  
    
      
    
    
      partial_embeds(mode)


        (optional)


        
          
        

    

  


  

      

          @callback partial_embeds(mode :: atom()) :: [atom()]


      



  


        

      

      
        Functions


        


  
    
      
    
    
      __using__(opts)


        (macro)


        
          
        

    

  


  

Adopts the contract: sets @behaviour Enact.InputSchema and imports
cast_input/4, nothing more.
Expands to exactly:
@behaviour Enact.InputSchema
import Enact.InputSchema, only: [cast_input: 3, cast_input: 4]
use Ecto.Schema, import Ecto.Changeset, and @primary_key false
stay explicit in the module.

  



    

  
    
      
    
    
      cast_input(base_or_changeset, params, fields, opts \\ [])



        
          
        

    

  


  

      

          @spec cast_input(struct() | Ecto.Changeset.t(), map(), [atom()], keyword()) ::
  Ecto.Changeset.t()


      


Casts scalar params with JSON API semantics.
A replacement for Ecto.Changeset.cast/4 in input-module changeset
heads. Ecto's stock cast implements HTML-form semantics: "" on any
field means "no value" and silently becomes nil, regardless of field
type. cast_input/4 derives empty-string handling from each field's
schema type instead:
	Input	Non-string field	:string field	:string in keep_empty_strings:
	"5", "true"	coerced via Ecto.Type	value as sent	value as sent
	"", " "	"is invalid" error	nil (empty → clear)	"" (empty is a value)
	null	nil	nil	nil
	omitted	untouched	untouched	untouched

Values are never modified: casting interprets input, it does not
transform it. A :string value is checked for emptiness with a trimmed
test (matching Ecto's own default, so " " counts as empty), but a
non-empty value passes through exactly as sent — " hi " keeps its
whitespace. Data hygiene such as trimming is a separate, explicit
concern for changeset heads or validations, not a cast side effect.
One option (anything else raises):
	:keep_empty_strings — :string fields whose empty disposition is
"" rather than nil, for NOT NULL DEFAULT '' columns where the
empty string is a value

Option fields must be :string fields on the schema; listing a field
outside a given head's cast list is allowed and inert, so option
attributes can be shared across mode heads with differing cast lists.
Normalization applies only to fields whose schema type is literally
:string and whose param value is a binary; custom types receive the
raw value and apply their own cast/1. :binary fields keep "" as a
value (it is a valid binary). Array fields are untouched: elements are
neither coalesced nor dropped — a "" element in an
{:array, :string} field passes through, so validate against empty
elements where they matter. Embed fields are not accepted — cast them
with Ecto.Changeset.cast_embed/3 as usual. Presence semantics are
unchanged: normalization rewrites values, never adds or removes keys,
so an empty string coalescing to nil still records a presence-visible
nil-clear.
Because validate_required/2 consults the changeset's stored
empty_values, a literal "" value satisfies required-ness when
cast_input/4 created the changeset (the documented pattern — base as
the first argument). For plain :string fields this changes nothing
(empties are already nil before validation); for
keep_empty_strings: fields it means validate_required expresses
"never nil, "" allowed". Note the stored empty_values comes from
whichever cast created the changeset — piping a stock cast into
cast_input keeps the stock default, under which "" fails
required-ness.
Required-ness, defaults, and null-rejection are out of scope; they stay
in changeset heads, DB columns, and action validate/2 respectively.
Enact.Test.assert_rejects_empty_strings/3 verifies the empty-string
outcome regardless of whether a module uses cast_input/4 or a stock
cast with empty_values: [].

  


        

      


  

    
Enact.Context 
    



      
The per-invocation context threaded through every pipeline step.
	actor — required, from opts; opaque to Enact (struct, scope, or
:anonymous) — only the host app's authorize/1 and fetchers read it
	subject — filled by the load step: the updated record (patch mode)
or the parent anchor (create-under-parent)
	params — caller params after key stringification (values still
raw), kept for presence checks (Enact.provided?/2) and audit
	repo — the injected repo module
	mode — :create or :patch, from the action's config/0
	assigns — caller-passed metadata merged with resolver-stashed
references (resolver keys win on collision)

        t()

      


    





      


      
        Types


        


  
    
      
    
    
      t()



        
          
        

    

  


  

      

          @type t() :: %Enact.Context{
  actor: term(),
  assigns: map(),
  mode: :create | :patch,
  params: map(),
  repo: module(),
  subject: struct() | nil
}


      



  


        

      


  

    
Enact.Error 
    



      
The closed error taxonomy for action results.
Every failed Enact.run/3, Enact.dry_run/3, Enact.subject/3, or
Enact.authorized/3 returns
{:error, %Enact.Error{}} with one of five types, each mapping to an
HTTP status:
	:invalid → 422 — bad input; carries the changeset (the only
outward-rich type; it describes the caller's own input)
	:forbidden → 403 — the actor may not perform this action
	:not_found → 404 — the URL-anchored subject does not exist
(or is outside the caller's tenant)
	:conflict → 409 — input was fine; the world changed
(optimistic/temporal races, confirmation-digest mismatch)
	:internal → 500 — a bug bucket; every production occurrence is
either a bug or a missing promotion to a real type

reason is a stable term for logs, telemetry, and the host renderer.
Do not echo it wholesale in responses. The default renderer maps type
to generic copy. To vary the message — usually on :forbidden — match
a host-owned reason in the renderer and keep the generic clause as
fallback. Store atoms, not user-facing strings. Do not use :not_found
reasons to distinguish "exists" from "not yours".
meta is for machine-readable extras (retry_after, stable error codes).
Actions never invent bespoke error types — the closed taxonomy means
the host app's renderer never grows a default clause for type.

        t()

      


    


    
      
        type()

      


    





  
    Functions
  


    
      
        conflict(reason \\ nil, meta \\ %{})

      


        Builds a :conflict error with an optional reason and meta.



    


    
      
        forbidden(reason \\ nil)

      


        Builds a :forbidden error with an optional reason.



    


    
      
        internal(reason)

      


        Builds an :internal error with a reason for logs and telemetry.



    


    
      
        invalid(changeset)

      


        Builds an :invalid error carrying the changeset.



    


    
      
        not_found(reason \\ nil)

      


        Builds a :not_found error with an optional reason.



    





      


      
        Types


        


  
    
      
    
    
      t()



        
          
        

    

  


  

      

          @type t() :: %Enact.Error{
  changeset: Ecto.Changeset.t() | nil,
  meta: map(),
  reason: term(),
  type: type()
}


      



  



  
    
      
    
    
      type()



        
          
        

    

  


  

      

          @type type() :: :invalid | :forbidden | :not_found | :conflict | :internal


      



  


        

      

      
        Functions


        


    

    

  
    
      
    
    
      conflict(reason \\ nil, meta \\ %{})



        
          
        

    

  


  

      

          @spec conflict(term(), map()) :: t()


      


Builds a :conflict error with an optional reason and meta.

  



    

  
    
      
    
    
      forbidden(reason \\ nil)



        
          
        

    

  


  

      

          @spec forbidden(term()) :: t()


      


Builds a :forbidden error with an optional reason.
The runner produces this from authorize/1: false yields no reason;
{:error, reason} stores that reason. Use a host-owned atom when the
renderer should vary the 403 copy. Do not echo reason wholesale.

  



  
    
      
    
    
      internal(reason)



        
          
        

    

  


  

      

          @spec internal(term()) :: t()


      


Builds an :internal error with a reason for logs and telemetry.

  



  
    
      
    
    
      invalid(changeset)



        
          
        

    

  


  

      

          @spec invalid(Ecto.Changeset.t()) :: t()


      


Builds an :invalid error carrying the changeset.

  



    

  
    
      
    
    
      not_found(reason \\ nil)



        
          
        

    

  


  

      

          @spec not_found(term()) :: t()


      


Builds a :not_found error with an optional reason.

  


        

      


  

    
Enact.Preview 
    



      
The result of Enact.dry_run/3 — a distinct struct so callers are
structurally unable to confuse "validated" with "executed".
	updates — Enact.updates/2 output: the canonical, post-
normalization "what will be persisted" map. What the user confirms
is definitionally what executes. Patch previews carry only the
provided keys; host apps render old → new diffs by comparing against
subject.
	subject — the record load_subject/2 returned, or nil. Compare
updates against it for old → new diffs. Not part of the digest.
	resolved — names of resolvers that succeeded. Never the loaded
structs — those stay in ctx.assigns and never reach the caller.
	digest — canonical hash binding the action, mode, locator params
(params keys not in the input schema), and updates map. Pass it
back as confirm_digest: to Enact.run/3, which recomputes
post-validation and returns :conflict on mismatch.

A preview is not a promise: no reservation semantics. The confirming
run/3 re-executes the full pipeline, and races surface as
:invalid/:conflict normally.

    Functions
  


    
      
        digest(action, mode, locators, updates)

      


        Canonically digests a pending change: "sha256:..." over the action
module, mode, locator params, and updates map together. Locator params
are params keys not in the input schema (fields/1) — typically the
URL-anchored subject id. Folding action, mode, and locators in makes
"the user confirmed this exact change to this record" total — a
digest minted for one action, mode, or subject never confirms another,
and input-less actions (whose updates are always %{}) don't collapse
across records.



    





      


      
        Types


        


  
    
      
    
    
      t()



        
          
        

    

  


  

      

          @type t() :: %Enact.Preview{
  action: module(),
  digest: String.t(),
  mode: :create | :patch,
  resolved: [atom()],
  subject: struct() | nil,
  updates: map()
}


      



  


        

      

      
        Functions


        


  
    
      
    
    
      digest(action, mode, locators, updates)



        
          
        

    

  


  

      

          @spec digest(module(), :create | :patch, map(), map()) :: String.t()


      


Canonically digests a pending change: "sha256:..." over the action
module, mode, locator params, and updates map together. Locator params
are params keys not in the input schema (fields/1) — typically the
URL-anchored subject id. Folding action, mode, and locators in makes
"the user confirmed this exact change to this record" total — a
digest minted for one action, mode, or subject never confirms another,
and input-less actions (whose updates are always %{}) don't collapse
across records.
The encoding is hand-rolled and injective — every node is type-tagged,
binaries and atom names are length-prefixed, and map entries are sorted
by encoded key at every depth. Elixir map ordering alone is not
sufficient (large maps enumerate in hash order), and the encoding avoids
term_to_binary, whose bytes are not guaranteed stable across OTP
releases — digests must survive the confirmation gap in a mixed-version
rolling deploy.

  


        

      


  

    
Enact.Guardrails 
    



      
Mechanical enforcement of input-schema invariants — every "just don't
do X" rule that is detectable gets detected and raised, upgrading
conventions to invariants.
The runner invokes assert_valid_input_schema!/2 automatically on an
action's first run (memoized per action). The memoization lives in
:persistent_term and survives dev code reloads, so editing an input
schema in a running server does not re-trigger the check until restart —
another reason host apps should also call it from a CI test on every
action's input module for compile-adjacent feedback:
for action <- MyApp.Actions.all(), input = action.input() do
  Enact.Guardrails.assert_valid_input_schema!(input,
    mode: Keyword.get(action.config(), :mode, :create)
  )
end

      


      
        Summary


  
    Functions
  


    
      
        assert_valid_input_schema!(module, opts \\ [])

      


        Walks an input module recursively (through its embeds, with a cycle
guard for self-referential schemas) and raises a teaching error on



    





      


      
        Functions


        


    

  
    
      
    
    
      assert_valid_input_schema!(module, opts \\ [])



        
          
        

    

  


  

Walks an input module recursively (through its embeds, with a cycle
guard for self-referential schemas) and raises a teaching error on:
	any scalar field with a non-nil default (embed fields excluded —
their structural []/nil defaults are fine)
	a primary key at any level
	associations at any level — embeds only
	top-level module only: missing changeset/3 or fields/1 exports,
or missing from_subject/1 when mode: :patch is given (nested item
modules are exempt — they implement changeset/2 for cast_embed)

Options: :mode — the referencing action's mode; :patch requires
from_subject/1.

  


        

      


  

    
Enact.Resolve 
    



      
Reference resolution — the pipeline step that turns payload references
(public-facing IDs like usr_XXXX) into loaded records.
Actions declare resolvers as data:
def resolvers do
  [
    # scalar
    owner: {:owner_id, &fetch_owner/2},
    # path form → batch (one level deep)
    milestone_owners: {[:milestones, :owner_id], &fetch_milestone_owners/2}
  ]
end
Resolution failures are field-level :invalid errors ("not found" on
the field), never :not_found — 404 belongs to the URL subject, and
"exists but not yours" must be indistinguishable from "doesn't exist".
All resolvers run and all failures are collected without
short-circuiting, tagged validation: :resolution so renderers can
distinguish reference errors from input-format errors without string
matching.
Scalar fetcher contract
(public_id, ctx) -> {:ok, struct} | :error | {:error, message}
Skipped when the caller did not provide the field (an untouched
reference on PATCH survives) and on explicit nil-clears (nothing to
resolve). A provided reference resolves even when identical to the
current value: re-resolution is re-authorization, and it keeps the
execute-side contract total — whenever a non-nil reference appears in
Enact.updates/2 output, the resolved record is in ctx.assigns. On
success the struct is stashed under the resolver name; execute/2
reads it there (ctx.assigns.owner.id) to translate public → internal
ids.
Batch fetcher contract (path form)
(ids, ctx) -> %{public_id => struct | {:error, message}}
The unique non-nil ids across the embed's item changesets are collected
into one fetcher call (N items ≠ N queries). Ids absent from the result
map render the generic "not found" on the item at its correct index;
{:error, message} values render precise per-item messages. On success
the lookup map is stashed under the resolver name, keyed by public id —
the execute-side join is a map read. Paths are one level deep only.
Error precision — the trust-anchor rule
Collapse is mandatory outside the trust anchor; precision is permitted
inside it. Missing and wrong-tenant must both produce bare :error
(generic "not found") — if they render differently, probing IDs
reveals which exist. Precise messages ({:error, "has been deactivated"}) are for records within the caller's own tenant only.
Safety comes from check ordering inside the fetcher: scope by the trust
anchor first; emit precise messages only about records the anchor-scoped
query returned.

      




  

    
Enact.Validations 
    



      
Changeset-pipeline combinators for action validate/2 callbacks.
These compose into ordinary Ecto.Changeset pipelines — they are
never replacements for validate_* functions. The dividing line for
where a rule lives: payload-intrinsic rules (format, bounds, inclusion)
belong in the input module's own validations; operation- and actor-aware
rules belong in the action's validate/2.

    Functions
  


    
      
        check(changeset, fun)

      


        Cheap gates expensive: no-ops when the changeset is already invalid,
otherwise applies fun. All DB-backed checks go through it, so garbage
input never triggers queries



    


    
      
        unique(changeset, field, opts)

      


        Scoped uniqueness for input changesets. Skips when the field has no
change (an untouched value on PATCH is already persisted).



    





      


      
        Functions


        


  
    
      
    
    
      check(changeset, fun)



        
          
        

    

  


  

      

          @spec check(Ecto.Changeset.t(), (Ecto.Changeset.t() -> Ecto.Changeset.t())) ::
  Ecto.Changeset.t()


      


Cheap gates expensive: no-ops when the changeset is already invalid,
otherwise applies fun. All DB-backed checks go through it, so garbage
input never triggers queries:
def validate(changeset, ctx) do
  changeset
  |> validate_length(:note, max: 500)
  |> check(&unique(&1, :slug, query: Project, repo: ctx.repo, scope: [org_id: ctx.actor.org_id], except: ctx.subject))
end

  



  
    
      
    
    
      unique(changeset, field, opts)



        
          
        

    

  


  

      

          @spec unique(Ecto.Changeset.t(), atom(), keyword()) :: Ecto.Changeset.t()


      


Scoped uniqueness for input changesets. Skips when the field has no
change (an untouched value on PATCH is already persisted).
Options:
	:query (required) — the persistence queryable to check against
	:repo (required) — usually ctx.repo
	:scope — keyword of extra column/value pairs to filter by
(tenancy scoping)
	:except — exclude the current row on PATCH. A struct (uses its
primary key), an id (integer / binary, compared to id), or a
keyword of column/value pairs. Soft-deletes stay on :query
(e.g. from(s in Schema, where: is_nil(s.deleted_at))).

Adds "has already been taken" on the field, tagged
validation: :unique. Like Ecto's unsafe_validate_unique/4 this is
best-effort pre-flight UX — keep the DB unique index and declared
constraint as the source of truth; the runner promotes constraint-error
changesets from execute to :invalid.

  


        

      


  

    
Enact.Delegates 
    



      
Opt-in helper that generates context one-liners for Enact.run/3,
Enact.dry_run/3, Enact.subject/3, and Enact.authorized/3.
Phoenix contexts remain the application API; this only writes the
forwarding functions hosts otherwise type by hand. It is not an
action-definition DSL — actions stay ordinary modules, and handwritten
delegates remain valid.
defmodule MyApp.Contacts do
  alias MyApp.Contacts.Actions.{CreateContact, UpdateContact}

  use Enact.Delegates, actions: [CreateContact, UpdateContact]

  # reads and load_subject fetchers stay here
end
For each action MyApp.Contacts.Actions.CreateContact, this defines:
def create_contact(params, opts),
  do: Enact.run(CreateContact, params, opts)

def create_contact_dry_run(params, opts),
  do: Enact.dry_run(CreateContact, params, opts)

def create_contact_subject(params, opts),
  do: Enact.subject(CreateContact, params, opts)

def create_contact_authorized(params, opts),
  do: Enact.authorized(CreateContact, params, opts)
Names come from the last segment of the module, underscored via
Macro.underscore/1. All four wrappers are generated for every listed
action. Bodies only forward — no param reshaping, no persistable fields
stamped in.
If a host wants a different public name or a non-forwarding body, omit
that module from the list and write the function by hand.

      




  

    
Enact.Test 
    



      
Shared test helpers for host-app action tests (and Enact's own suite).
import Enact.Test

test "rejects a blank name" do
  {:error, _} = result = Enact.run(CreateProject, %{"name" => ""}, actor: actor)
  assert_invalid(result, on: :name)
end
Intended for the test environment; the assertions require ExUnit.

        assert_invalid(result, opts \\ [])

      


        Asserts the result is {:error, %Enact.Error{type: :invalid}}, and —
given on: field — that the changeset carries an error on that
top-level field. Returns the changeset for further assertions.



    


    
      
        assert_rejects_empty_strings(module, mode, opts \\ [])

      


        Asserts that an input module rejects "" on every non-string castable
field for the given mode.



    


    
      
        build_ctx(opts \\ [])

      


        Builds an Enact.Context for unit-testing validate/2 callbacks or
fetchers directly, without running the pipeline.



    


    
      
        errors_on(changeset)

      


        Flattens a changeset's errors into a map of field → messages, with
nested embed errors as per-index lists of maps — the conventional
errors_on helper, shipped so host apps don't reinvent it.

      assert_invalid(result, opts \\ [])



        
          
        

    

  


  

      

          @spec assert_invalid(
  term(),
  keyword()
) :: Ecto.Changeset.t()


      


Asserts the result is {:error, %Enact.Error{type: :invalid}}, and —
given on: field — that the changeset carries an error on that
top-level field. Returns the changeset for further assertions.

  



    

  
    
      
    
    
      assert_rejects_empty_strings(module, mode, opts \\ [])



        
          
        

    

  


  

      

          @spec assert_rejects_empty_strings(module(), atom(), keyword()) :: :ok


      


Asserts that an input module rejects "" on every non-string castable
field for the given mode.
Ecto's default cast silently coerces "" to nil on any field type.
For non-string fields that turns malformed input into a null-clear
instruction instead of a cast error. This probe calls
module.changeset/3 with "" for each non-string scalar field in
fields(mode) and fails unless the field carries a cast error —
regardless of whether the module uses Enact.InputSchema.cast_input/4
or a stock cast with empty_values: [].
Probing is safe because input modules are dependency-free by contract
(no ctx, no repo). Errors on other fields (for example
validate_required) are ignored; only the probed field's cast outcome
is checked. :string, :binary, and :binary_id fields are skipped:
"" is a valid value for the first two, and :binary_id's
changeset-level cast accepts any binary (its format is validated at dump
time). A rejection counts when the probed field carries any error other
than validation: :required — custom types may tag rejections with
their own metadata (Ecto.Enum uses :inclusion), while a :required
error is the footgun's own signature: "" silently coerced to nil,
then caught downstream.
Coverage is top-level only: item schemas have no fields/1 manifest,
so their cast lists are not introspectable. Item-level strictness is a
convention — cast item fields with cast_input/4 — rather than a
probed guarantee.
Options: :except — fields whose custom types accept "" deliberately.

  



    

  
    
      
    
    
      build_ctx(opts \\ [])



        
          
        

    

  


  

      

          @spec build_ctx(keyword()) :: Enact.Context.t()


      


Builds an Enact.Context for unit-testing validate/2 callbacks or
fetchers directly, without running the pipeline.
Options (all optional): :actor (default :test_actor), :subject,
:params (default %{}), :repo, :mode (default :create),
:assigns (default %{}).
:params are stored as given — this helper does not stringify keys.
Enact.run/3 / dry_run/3 / subject/3 / authorized/3 do. Pass string keys here if the code
under test pattern-matches on them.

  



  
    
      
    
    
      errors_on(changeset)



        
          
        

    

  


  

      

          @spec errors_on(Ecto.Changeset.t()) :: map()


      


Flattens a changeset's errors into a map of field → messages, with
nested embed errors as per-index lists of maps — the conventional
errors_on helper, shipped so host apps don't reinvent it.
assert %{milestones: [%{}, %{owner_id: ["not found"]}]} = errors_on(changeset)

  


        

      


  OEBPS/dist/epub-4WIP524F.js
(()=>{var s=document.querySelector.bind(document),o=document.querySelectorAll.bind(document);function r(e){document.readyState!=="loading"?e():document.addEventListener("DOMContentLoaded",e)}var l="hll";window.addEventListener("exdoc:loaded",t);function t(){o("[data-group-id]").forEach(e=>{e.addEventListener("mouseenter",i),e.addEventListener("mouseleave",i)})}function i(e){let n=e.currentTarget,a=e.type==="mouseenter",c=n.getAttribute("data-group-id");n.parentElement.querySelectorAll(`[data-group-id="${c}"]`).forEach(u=>{u.classList.toggle(l,a)})}r(()=>{t()});})();




